Example Program 17: MM_S17_Vis_ParseLabel

You are currently viewing the documentation for the latest version (2.1.0). To access a different version, click the "Switch version" button located in the upper-right corner of the page.

■ If you are not sure which version of the product you are currently using, please feel free to contact Mech-Mind Technical Support.

Program Introduction

Description

The robot triggers the Mech-Vision project to run to obtain the vision result, parses the labels, and then adopts a handling method based on the label to perform picking and placing.

File path

You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the Communication Component/Robot_Interface/YASKAWA/sample/MM_S17_Vis_ParseLabel path.

Project

Mech-Vision project (data needs to exist in the labels port of the Output Step)

Prerequisites

You have set up the Standard Interface communication.
Automatic calibration is completed.

This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario.

Program Description

This part describes the MM_S17_Vis_ParseLabel example program.

The only difference between the MM_S17_Vis_ParseLabel example program and the MM_S1_Vis_Basic example program is that MM_S17_Vis_ParseLabel can parse labels (the code of this feature is bolded). As such, only the feature of parsing labels is described in the following section. For information about the parts of MM_S17_Vis_ParseLabel that are consistent with those of MM_S1_Vis_Basic, see Example Program 1: MM_S1_Vis_Basic.

NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project and get vision result,
'then parse the label info
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P070 P070
SUB P071 P071
'set 100mm to z of P070
SETE P070 (3) 100000
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'get vision result from NO.1
'Mech-Vision project
CALL JOB:MM_GET_VISDATA ARGF"1;51;52"
'check whether vision result has
'been got from Mech-Vision
'successfully
IFTHENEXP I052<>1100
	'add error handling logic here
	'according to different error
	'codes
	'e.g.: I052=1003 means no point
	'cloud in ROI
	'e.g.: I052=1002 means no
	'vision result
	 PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save first vision point data to
'local variables
CALL JOB:MM_GET_POSE ARGF"1;71;61;62"
'parse label info received from
'Mech-Vision, eg. "I061=56" will
'decompose into 5 and 6
SET I064 I061
SET I065 I061
'I064=5
DIV I064 10
SET I063 I064
MUL I063 10
'I065=6
SUB I065 I063
IFTHENEXP I064=5
	'add handling logic a
	 PAUSE
ELSE
	'add handling logic b
	 PAUSE
ENDIF
'move to intermediate waypoint of
'picking
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to picking waypoint
MOVL P071 V=50.0 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to intermediate waypoint of
'placing
MOVJ C00003 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00004 V=166.6 PL=0
'move to placing waypoint
MOVL C00005 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00006 V=166.6 PL=0
'move back to robot home position
MOVJ C00007 VJ=50.00
END

The workflow corresponding to the above example program code is shown in the figure below.

The table below describes the feature of parsing labels. You can click the hyperlink to the command name to view its detailed description.

Feature Code and description

Feature	Code and description
Parse labels	The MM_GET_POSE command stores the TCP, label and tool ID of the vision point in the P071, I61, and I62 variables respectively. This example assumes that the value of the I061 variable is 56. `SET I064 I061 SET I065 I061` After the above assignment statements are executed, the values of the variables I064 and I065 are 56. `'I064=5 DIV I064 10 SET I063 I064 MUL I063 10 'I065=6 SUB I065 I063` DIV I064 10: Divide the value of I064 by 10 and assigns the quotient to I064, resulting in the value of I064 being 5. SET I063 I064: Assign the value of I064 to I063, resulting in the value of I063 being 5. MUL I063 10: Multiply the value of I063 by 10 (5 × 10) and assign the result to I063, resulting in the value of I063 being 50. SUB I065 I063: Subtract the value of I063 from the value of I065 (56 - 50) and assign the result to I065, resulting in the value of I065 being 6. The above code parses I061 into I064 and I065 (i.e., 56 is parsed into 5 and 6).
Adopt a handling method based on the label parsing result	`IFTHENEXP I064=5 'add handling logic a PAUSE ELSE 'add handling logic b PAUSE ENDIF` The above code indicates that if I064 is 5, logic a will be executed; otherwise, logic b will be executed. The handling method varies based on the label parsing result. You can adopt a handling method based on your business requirement.

Parse labels

The MM_GET_POSE command stores the TCP, label and tool ID of the vision point in the P071, I61, and I62 variables respectively. This example assumes that the value of the I061 variable is 56.

SET I064 I061
SET I065 I061

After the above assignment statements are executed, the values of the variables I064 and I065 are 56.

'I064=5
DIV I064 10
SET I063 I064
MUL I063 10
'I065=6
SUB I065 I063

DIV I064 10: Divide the value of I064 by 10 and assigns the quotient to I064, resulting in the value of I064 being 5.
SET I063 I064: Assign the value of I064 to I063, resulting in the value of I063 being 5.
MUL I063 10: Multiply the value of I063 by 10 (5 × 10) and assign the result to I063, resulting in the value of I063 being 50.
SUB I065 I063: Subtract the value of I063 from the value of I065 (56 - 50) and assign the result to I065, resulting in the value of I065 being 6.

The above code parses I061 into I064 and I065 (i.e., 56 is parsed into 5 and 6).

Adopt a handling method based on the label parsing result

IFTHENEXP I064=5
	'add handling logic a
	 PAUSE
ELSE
	'add handling logic b
	 PAUSE
ENDIF

The above code indicates that if I064 is 5, logic a will be executed; otherwise, logic b will be executed. The handling method varies based on the label parsing result. You can adopt a handling method based on your business requirement.

Example Program 17: MM_S17_Vis_ParseLabel

Program Introduction

Program Description

We Value Your Privacy