サンプルプログラム16：MM_S16_Viz_GetDirection

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Viz ;
   3:  !project, then get planned path ;
   4:  !and get box direction using ;
   5:  !command 210 ;
   6:  !Mech-Mind, 2023-12-25 ;
   7:  !-------------------------------- ;
   8:   ;
   9:  !set current uframe NO. to 0 ;
  10:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  11:  !set current tool NO. to 1 ;
  12:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  13:  !move to robot home position ;
  14:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  15:  !initialize communication ;
  16:  !parameters(initialization is ;
  17:  !required only once) ;
  18:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  19:  !move to image-capturing position ;
  20:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  21:  !trigger Mech-Viz project ;
  22:  ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10) ;
  23:  !get planned path ;
  24:  ﾖﾋﾞﾀﾞｼ MM_GET_PLNDT(0,3,51,52,53) ;
  25:  !check whether planned path has ;
  26:  !been got from Mech-Viz ;
  27:  !successfully ;
  28:  ﾓｼ ﾚｼﾞ[53]<>2100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  29:  !get gripper control signal list ;
  30:  ﾖﾋﾞﾀﾞｼ MM_GET_DL(0,0) ;
  31:  !save waypoints of the planned ;
  32:  !path to local variables one ;
  33:  !by one ;
  34:  ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(1,3,60,61,62,63,64,70) ;
  35:  ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(2,3,61,91,92,93,94,100) ;
  36:  ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(3,3,62,121,122,123,124,130) ;
  37:  !get box direction status from ;
  38:  !planned results of 2nd point ;
  39:  ﾚｼﾞ[10]=ﾚｼﾞ[116]    ;
  40:  !follow the planned path to pick ;
  41:  !move to approach waypoint ;
  42:  !of picking ;
  43:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ    ;
  44:  !move to picking waypoint ;
  45:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ    ;
  46:  !add object grasping logic here ;
  47:  ｲﾁｼﾞﾃｲｼ ;
  48:  !set gripper control signal ;
  49:  ﾖﾋﾞﾀﾞｼ MM_SET_DL(0)    ;
  50:  !move to departure waypoint ;
  51:  !of picking ;
  52:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ    ;
  53:  !place the box according to its ;
  54:  !direction ;
  55:  ﾓｼ ﾚｼﾞ[10]=0,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
  56:  ﾓｼ ﾚｼﾞ[10]<>0,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[2] ;
  57:   ;
  58:  ﾗﾍﾞﾙ[1:place position 1] ;
  59:  !move to intermediate waypoint ;
  60:  !of placing ;
  61:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  62:  !move to approach waypoint ;
  63:  !of placing ;
  64:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  65:  !move to placing waypoint ;
  66:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ    ;
  67:  !add object releasing logic here, ;
  68:  !such as "DO[1]=OFF" ;
  69:  ｲﾁｼﾞﾃｲｼ ;
  70:  !move to departure waypoint ;
  71:  !of placing ;
  72:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  73:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[3] ;
  74:   ;
  75:  ﾗﾍﾞﾙ[2:place position 2] ;
  76:  !move to intermediate waypoint ;
  77:  !of placing ;
  78:ｶｸｼﾞｸ ｲﾁ[5] 50% ﾅﾒﾗｶ100    ;
  79:  !move to approach waypoint ;
  80:  !of placing ;
  81:ﾁｮｸｾﾝ ｲﾁ[6] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  82:  !move to placing waypoint ;
  83:ﾁｮｸｾﾝ ｲﾁ[6] 300mm/sec ｲﾁｷﾞﾒ    ;
  84:  !add object releasing logic here, ;
  85:  !such as "DO[1]=OFF" ;
  86:  ｲﾁｼﾞﾃｲｼ ;
  87:  !move to departure waypoint ;
  88:  !of placing ;
  89:ﾁｮｸｾﾝ ｲﾁ[6] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  90:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[3] ;
  91:   ;
  92:  ﾗﾍﾞﾙ[3] ;
  93:  !move back to robot home position ;
  94:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  95:  ｼｭｳﾘｮｳ ;
  96:   ;
  97:  ﾗﾍﾞﾙ[99:vision error] ;
  98:  !add error handling logic here ;
  99:  !according to different ;
 100:  !error codes ;
 101:  !e.g.: status=2038 means no ;
 102:  !point cloud in ROI ;
 103:  ｲﾁｼﾞﾃｲｼ ;