サンプルプログラム13：MM_S13_Vis_MoveInAdvance

現在ご覧いただいているのは最新版の内容です（V2.1.2）。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ ご利用中のバージョンが分からない場合や、サポートが必要な場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

Mech-Visionプロジェクトをトリガーした後、ロボットがカメラ撮影が完了した時点で移動でき、Mech-Visionプロジェクトの実行が終了するのを待機する必要はありません。このサンプルは、カメラがEIH方式で取り付けられている場合に適しています。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/ABB/sample/MM_S13_Vis_MoveInAdvance。

RobotWare6システムを使用する場合、ファイルの拡張子は .mod です。RobotWare7システムを使用する場合、ファイルの拡張子を .mod から .modx に変更する必要があります。

必要なプロジェクト

Mech-Visionプロジェクト（EIHカメラ取り付け方式）

使用前提

  1. 標準インターフェース通信設定が完了したこと。

  2. 自動キャリブレーションが完了したこと。
このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S13_Vis_MoveInAdvanceサンプルプログラムのコードと関連する説明です。

このサンプルは、MM_S1_Vis_Basicサンプルに比べて、「撮影完了後に移動できる」機能（太字部分のコード）のみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください）。 
MODULE MM_S13_Vis_MoveInAdvance
!----------------------------------------------------------
! FUNCTION: trigger Mech-Vision project then move to
! wait position and get vision pose in EIH setup
! Mech-Mind, 2023-12-25
!----------------------------------------------------------
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num toolid:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_wait_point:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[-66.3475,-105.248,985.956],[0.000237259,-0.998599,0.0528747,0.00188901],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

PROC Sample_13()
    !set the acceleration parameters
    AccSet 50, 50;
    !set the velocity parameters
    VelSet 50, 1000;
    !move to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
    !initialize communication parameters (initialization is required only once)
    MM_Init_Socket "127.0.0.1",50000,300;
    !move to image-capturing position
    MoveL camera_capture,v1000,fine,gripper1;
    !open socket connection
    MM_Open_Socket;
    !trigger NO.1 Mech-Vision project
    MM_Start_Vis 1,0,1,snap_jps;
    !move to wait position for picking
    MoveL pick_wait_point,v1000,z50,gripper1;
    !get vision result from NO.1 Mech-Vision project
    MM_Get_VisData 1,pose_num,status;
    !check whether vision result has been got successfully
    IF status<>1100 THEN
        !add error handling logic here according to different error codes
        !e.g.: status=1003 means no point cloud in ROI
        !e.g.: status=1002 means no vision result
        Stop;
    ENDIF
    !close socket connection
    MM_Close_Socket;
    !save first vision point data to local variables
    MM_Get_Pose 1,pickpoint,label,toolid;
    !move to intermediate waypoint of picking
    MoveJ pick_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to picking waypoint
    MoveL pickpoint,v300,fine,gripper1;
    !add object grasping logic here, such as "setdo DO_1, 1;"
    Stop;
    !move to departure waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to intermediate waypoint of placing
    MoveJ drop_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move to placing waypoint
    MoveL drop,v300,fine,gripper1;
    !add object releasing logic here, such as "setdo DO_1, 0;"
    Stop;
    !move to departure waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move back to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
ENDPROC
ENDMODULE

上記のサンプルプログラムの処理流れは、下図の通りです。

sample13

下表は、「撮影完了後に移動できる」機能のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細を確認できます。

処理流れ コートと説明

ロボットが撮影完了後に移動できる

 
!trigger NO.1 Mech-Vision project
MM_Start_Vis 1,0,1,snap_jps;

  • MM_Start_Vis：Mech-Visionプロジェクトの実行をトリガーするためのコマンド。

  • 1：Mech-Visionプロジェクト番号。

  • 0：Mech-Visionプロジェクトがすべてのビジョンポイントを返すことを期待します。

  • 1：ロボットの現在の関節角度とフランジ位置姿勢をMech-Visionプロジェクトに送信します。カメラの取り付け方式がEIHの場合、ここは通常1に設定されます。

  • snap_jps：ユーザーによりカスタマイズされた関節角度。本プログラムでは、関節角度は使用されませんが、設定する必要があります。

EIHシーンでは、Mech-Visionプロジェクトの実行が終了するのを待たずに、カメラの撮影完了後にロボットが移動できるようにするために、Mech-Visionソフトウェア内で ロボット通信設定  次へ  詳細設定 を選択し、撮影完了後、「1102：トリガー成功」を返す にチェックを入れます。これにより、ロボットはMech-Visionプロジェクトをトリガーし、「1102：トリガー成功」を受信した後、移動を開始できるようになり、サイクルタイムを短縮できます。

下図のように設定していない場合、Mech-Visionプロジェクトが正常に実行されると、ビジョンシステムは直ちに「1102」ステータスコードをロボットに返します。このとき、ロボットは撮影が完了したかどうか判断できないため、移動することはできません。したがって、ロボットはMech-Visionプロジェクトが終了するのを待つ必要があります。

ビジョンシステムから返された「1102」ステータスコードは、MM_Start_Visコマンド内部で処理されます。下図のような設定を完了した場合、MM_Start_Visコマンドの実行が完了した後、ロボットは移動を開始できます。
configure communication 
!move to wait position for picking
MoveL pick_wait_point,v1000,z50,gripper1;

上記のコードは、ロボットが撮影後に把持の待機点に移動できることを意味します。これにより、Mech-Visionプロジェクトの実行とロボットの移動を並行して行うことができ、サイクルタイムを短縮することができます。

MM_S1_Vis_Basic サンプルとの違いにご注意ください。MM_S1_Vis_Basicサンプルでは、ロボットはMech-Visionプロジェクトの実行が終了した後に移動できますが、本サンプルではロボットはカメラの撮影が完了した後にすぐに移動できるようになっています。

この情報は役に立ちましたか？

ご意見・ご要望がございましたら、以下よりお寄せください：

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。

  • Preference
  • 同意する
  • 拒否する