サンプルプログラム2：MM_S2_Viz_Basic
プログラム概要
機能 |
ロボットがMech-Vizプロジェクトをトリガーして実行し、その後計画された経路を取得して、把持および配置を実行します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-VisionとMech-Vizプロジェクト |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S2_Viz_Basicサンプルプログラムのコードと関連する説明です。
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project and get planned path ;
4: !Mech-Mind, 2023-12-25 ;
5: !-------------------------------- ;
6: ;
7: !set current uframe NO. to 0 ;
8: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
9: !set current tool NO. to 1 ;
10: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
11: !move to robot home position ;
12:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
13: !initialize communication ;
14: !parameters(initialization is ;
15: !required only once) ;
16: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
17: !move to image-capturing position ;
18:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
19: !trigger Mech-Viz project ;
20: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10) ;
21: !get planned path, 1st argument ;
22: !(1) means getting pose in JPs ;
23: ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
24: !check whether planned path has ;
25: !been got from Mech-Viz ;
26: !successfully ;
27: ﾓｼ ﾚｼﾞ[53]<>2100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
28: !save waypoints of the planned ;
29: !path to local variables one ;
30: !by one ;
31: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
32: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
33: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
34: !follow the planned path to pick ;
35: !move to approach waypoint ;
36: !of picking ;
37:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ ;
38: !move to picking waypoint ;
39:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ ;
40: !add object grasping logic here, ;
41: !such as "DO[1]=ON" ;
42: ｲﾁｼﾞﾃｲｼ ;
43: !move to departure waypoint ;
44: !of picking ;
45:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ ;
46: !move to intermediate waypoint ;
47: !of placing ;
48:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
49: !move to approach waypoint ;
50: !of placing ;
51:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
52: !move to placing waypoint ;
53:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ ;
54: !add object releasing logic here, ;
55: !such as "DO[1]=OFF" ;
56: ｲﾁｼﾞﾃｲｼ ;
57: !move to departure waypoint ;
58: !of placing ;
59:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
60: !move back to robot home position ;
61:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
62: ｼｭｳﾘｮｳ ;
63: ;
64: ﾗﾍﾞﾙ[99:vision error] ;
65: !add error handling logic here ;
66: !according to different ;
67: !error codes ;
68: !e.g.: status=2038 means no ;
69: !point cloud in ROI ;
70: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は上記のプログラムのコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 | ||
|---|---|---|---|
座標系設定 |
上記の2つのコマンドは、現在選択されているユーザー座標系とツール座標系を設定することを意味します。 |
||
Home位置に移動 |
このコマンドは、ロボットが関節移動の方式で設定されたHome位置に移動することを意味します。
|
||
通信初期化 |
このコマンドは、ロボットが MM_INIT_SKT コマンドを使用して、通信対象（IPC）のIPアドレス、ポート番号、およびタイムアウト待機時間を指定し、ビジョンシステムとの接続を確立することを意味します。
|
||
撮影位置に移動 |
このコマンドは、ロボットが直線移動の方式で設定された撮影位置に移動することを意味し、移動速度は1000mm/秒です。
|
||
Mech-Vizプロジェクトをトリガー |
このコマンドは、ロボットがビジョンシステムをトリガーしてMech-Vizプロジェクトを実行し、Mech-VizがMech-Visionから出力されたビジョン結果に基づいて把持経路を計画することを意味します。 |
||
計画された経路を取得 |
このコマンドは、ロボットがMech-Vizプロジェクトから返された計画経路を取得することを意味します。
上記のコードは、ステータスコードﾚｼﾞ[53]が2100の場合、ロボットがすべての計画された経路を正常に取得することを意味し、それ以外の場合はビジョンシステムに異常が発生し、プログラムはﾗﾍﾞﾙ[99]にジャンプして実行を続けることを意味します。以下にﾗﾍﾞﾙ[99]のコードを示します。 ユーザーは、特定のエラーコードに応じて適切な処理を行うことが可能です。本サンプルでは、すべてのエラーコードに対して同一の処理を行い、PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドを使用してプログラムの実行を停止しています。 |
||
計画された経路を保存 |
「ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80)」コマンドは、最初の経路点の関節角度、ラベル、およびロボットハンド番号をそれぞれ指定されたレジスタに保存することを意味します。
|
||
把持のアプローチ点に移動 |
ロボットが把持のアプローチ点（ｲﾁﾚｼﾞ[60]が表す位置）に移動します。 |
||
把持点に移動 |
ロボットが把持点（ｲﾁﾚｼﾞ[61]が表す位置）に移動します。 |
||
DO設定による把持 |
ロボットが把持点に到達した後、DOコマンド（例えば「DO[1]=ON」）を設定して、ロボットハンドを制御し、ワークを把持します。実際の状況に応じてDO設定を調整する必要があります。
|
||
把持の離れる点に移動 |
ロボットが把持の離れる点（ｲﾁﾚｼﾞ[62]が表す位置）に移動します。 |
||
中間点に移動 |
このコマンドは、ロボットが関節移動の方式で、把持の離れる点と配置のアプローチ点の間の中間点に移動することを意味します。
|
||
配置のアプローチ点に移動 |
|
||
配置点に移動 |
ロボットが配置のアプローチ点から配置点に移動します。 |
||
DO設定による配置 |
ロボットが配置点に到達した後、DOコマンド（例えば「DO[1]=OFF」）を設定して、ロボットハンドを制御し、ワークを配置します。実際の状況に応じてDO設定を調整する必要があります。
|
||
配置の離れる点に移動 |
ロボットは配置点の上方の所定位置に移動し、これを配置の離れる点と呼びます。
|
||
Home位置に移動 |
ロボットが配置の離れる点からHome位置に戻ります。 |