サンプルプログラム1：MM_S1_Vis_Basic

現在ご覧いただいているのは最新版の内容です（V2.1.2）。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ ご利用中のバージョンが分からない場合や、サポートが必要な場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

ロボットがMech-Visionプロジェクトをトリガーして実行し、その後ビジョン結果を取得して、把持および配置を実行します。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/FANUC/sample/MM_S1_Vis_Basic。

必要なプロジェクト

Mech-Visionプロジェクト

使用前提

  1. 標準インターフェース通信設定 が完了しました。

  2. 自動キャリブレーション が完了しました。
このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S1_Vis_Basicサンプルプログラムのコードと関連する説明です。

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project and get vision result ;
   4:  !Mech-Mind, 2023-12-25 ;
   5:  !-------------------------------- ;
   6:   ;
   7:  !set current uframe NO. to 0 ;
   8:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
   9:  !set current tool NO. to 1 ;
  10:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  11:  !move to robot home position ;
  12:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  13:  !initialize communication ;
  14:  !parameters(initialization is ;
  15:  !required only once) ;
  16:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  17:  !move to image-capturing position ;
  18:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  19:  !trigger NO.1 Mech-Vision project ;
  20:  ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10) ;
  21:  !get vision result from NO.1 ;
  22:  !Mech-Vision project ;
  23:  ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;
  24:  !check whether vision result has ;
  25:  !been got from Mech-Vision ;
  26:  !successfully ;
  27:  ﾓｼ ﾚｼﾞ[53]<>1100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  28:  !save first vision point data to ;
  29:  !local variables ;
  30:  ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;
  31:  !move to intermediate waypoint ;
  32:  !of picking ;
  33:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  34:  !move to approach waypoint ;
  35:  !of picking ;
  36:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  37:  !move to picking waypoint ;
  38:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ    ;
  39:  !add object grasping logic here, ;
  40:  !such as "DO[1]=ON" ;
  41:  ｲﾁｼﾞﾃｲｼ ;
  42:  !move to departure waypoint ;
  43:  !of picking ;
  44:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  45:  !move to intermediate waypoint ;
  46:  !of placing ;
  47:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  48:  !move to approach waypoint ;
  49:  !of placing ;
  50:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  51:  !move to placing waypoint ;
  52:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ    ;
  53:  !add object releasing logic here, ;
  54:  !such as "DO[1]=OFF" ;
  55:  ｲﾁｼﾞﾃｲｼ ;
  56:  !move to departure waypoint ;
  57:  !of placing ;
  58:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  59:  !move back to robot home position ;
  60:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  61:  ｼｭｳﾘｮｳ ;
  62:   ;
  63:  ﾗﾍﾞﾙ[99:vision error] ;
  64:  !add error handling logic here ;
  65:  !according to different ;
  66:  !error codes ;
  67:  !e.g.: status=1003 means no ;
  68:  !point cloud in ROI ;
  69:  !e.g.: status=1002 means no ;
  70:  !vision results ;
  71:  ｲﾁｼﾞﾃｲｼ ;

上記のサンプルプログラムの処理流れは、下図の通りです。

sample1

下表は上記のプログラムのコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。

処理流れ コートと説明

座標系設定

 
   7:  !set current uframe NO. to 0 ;
   8:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
   9:  !set current tool NO. to 1 ;
  10:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;

  • ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0：現在選択されているユーザー座標系番号を0（ワールド座標系）に設定します。

  • ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1：現在選択されているツール座標系番号を1に設定します（ユーザーは事前に1番ツール座標系を設定する必要があります）。

上記の2つのコマンドは、現在選択されているユーザー座標系とツール座標系を設定することを意味します。

Home位置に移動

 
  11:  !move to robot home position ;
  12:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;

  • ｶｸｼﾞｸ：ロボットの関節移動コマンドで、ロボットが円弧型の経路に沿って指定された位置に移動することを意味します。

  • ｲﾁ[1]：ロボットが移動する目標位置を指定します。この場合、ティーチング法で設定されたHome位置を指します。通常、この位置はロボットがワークや周辺機器から安全な位置に離れている場所です。

  • 100%：最大移動速度に対する相対的な移動速度の割合を示します。

  • ｲﾁｷﾞﾒ：ロボットが目標位置に到達した際に、少し停止してから次の目標位置に移動することを意味します。

このコマンドは、ロボットが関節移動の方式で設定されたHome位置に移動することを意味します。

Home位置（ｲﾁ[1]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

通信初期化

 
  13:  !initialize communication ;
  14:  !parameters(initialization is ;
  15:  !required only once) ;
  16:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;

  • MM_INIT_SKT：通信を初期化するためのコマンド。

  • '8'：ロボットのポート番号。

  • '127.0.0.1'：IPCのIPアドレス。

  • 50000：IPCのポート番号。

  • 5：通信のタイムアウト待機時間（5分間）。

このコマンドは、ロボットが MM_INIT_SKT コマンドを使用して、通信対象（IPC）のIPアドレス、ポート番号、およびタイムアウト待機時間を指定し、ビジョンシステムとの接続を確立することを意味します。

実際の状況に基づいてIPCのIPアドレスやポート番号を変更し、ビジョンシステムで設定されたパラメータと一致するようにする必要があります。

撮影位置に移動

 
  17:  !move to image-capturing position ;
  18:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;

  • ﾁｮｸｾﾝ：ロボットの直線移動コマンドで、ロボットが指定された位置まで直線的に移動することを意味します。

  • ｲﾁ[2]：ロボットが移動する目標位置を指定します。この場合、ティーチング法で設定された撮影位置を指します。撮影位置とは、カメラが画像を撮影したときにロボットがいる位置を指します。この位置では、ロボットアームがカメラ視野を遮らないようにする必要があります。

このコマンドは、ロボットが直線移動の方式で設定された撮影位置に移動することを意味し、移動速度は1000mm/秒です。

撮影位置（ｲﾁ[2]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

Mech-Visionプロジェクトをトリガー

 
  19:  !trigger NO.1 Mech-Vision project ;
  20:  ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10) ;

  • MM_START_VIS：Mech-Visionプロジェクトの実行をトリガーするためのコマンド。

  • 1：Mech-Visionプロジェクト番号。

  • 0：Mech-Visionプロジェクトがすべてのビジョンポイントを返すことを期待します。

  • 2：ロボットの現在のフランジ位置姿勢をMech-Visionプロジェクトに送信します。

  • 10：ｲﾁﾚｼﾞ[10]の番号。このレジスタはカスタマイズされた関節角度データを保存します。本サンプルではこのデータに実際の用途はありませんが、位置レジスタの番号を必ず設定する必要があります。

このコマンドは、ロボットがビジョンシステムをトリガーして番号1のMech-Visionプロジェクトを実行し、Mech-Visionプロジェクトがすべてのビジョンポイントを返すことを期待することを意味します。

ビジョン結果を取得

 
  21:  !get vision result from NO.1 ;
  22:  !Mech-Vision project ;
  23:  ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;

  • MM_GET_VIS：ビジョン結果を取得するためのコマンド。

  • 1：Mech-Visionプロジェクト番号。

  • 51：ﾚｼﾞ[51]の番号。このレジスタは取得したビジョンポイント数を保存します。

  • 53：ﾚｼﾞ[53]の番号。このレジスタはコマンド実行のステータスコードを保存します。

このコマンドは、ロボットがMech-Visionプロジェクト1から返されたビジョン結果を取得することを意味します。

返されたビジョン結果はロボットのメモリに保存されるため、この時点ではユーザーがビジョン結果を直接取得することはできません。その後の「ビジョン結果を保存」コマンドを実行することで、結果を取得することができます。 
  24:  !check whether vision result has ;
  25:  !been got from Mech-Vision ;
  26:  !successfully ;
  27:  ﾓｼ ﾚｼﾞ[53]<>1100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;

  • 「ﾓｼ A,ｼﾞｬﾝﾌﾟ B」：条件Aが成立した場合、プログラムはBにジャンプして実行を続けます。

  • <>：等しくないことを意味します。

上記のコードは、ステータスコードﾚｼﾞ[53]が1100の場合、ロボットがすべてのビジョン結果を正常に取得することを意味し、それ以外の場合はビジョンシステムに異常が発生し、プログラムはﾗﾍﾞﾙ[99]にジャンプして実行を続けることを意味します。以下にﾗﾍﾞﾙ[99]のコードを示します。

  63:  ﾗﾍﾞﾙ[99:vision error] ;
  64:  !add error handling logic here ;
  65:  !according to different ;
  66:  !error codes ;
  67:  !e.g.: status=1003 means no ;
  68:  !point cloud in ROI ;
  69:  !e.g.: status=1002 means no ;
  70:  !vision results ;
  71:  ｲﾁｼﾞﾃｲｼ ;

ユーザーは、特定のエラーコードに応じて適切な処理を行うことが可能です。本サンプルでは、すべてのエラーコードに対して同一の処理を行い、PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドを使用してプログラムの実行を停止しています。

ビジョン結果を保存

 
  28:  !save first vision point data to ;
  29:  !local variables ;
  30:  ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;

  • MM_GET_POS：ビジョン結果を保存するためのコマンド。

  • 1：最初のビジョンポイントを保存します。

  • 60：ｲﾁﾚｼﾞ[60]の番号。このレジスタは最初のビジョンポイント（把持点）のツール位置姿勢を保存します。

  • 70：ﾚｼﾞ[70]の番号。このレジスタは最初のビジョンポイントに対応するラベルを保存します。

  • 80：ﾚｼﾞ[80]の番号。このレジスタは最初のビジョンポイントに対応するロボットハンド番号を保存します。

このコマンドは、最初のビジョンポイントのツール位置姿勢、ラベル、およびロボットハンド番号をそれぞれ指定されたレジスタに保存することを意味します。

中間点に移動

 
  31:  !move to intermediate waypoint ;
  32:  !of picking ;
  33:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;

  • ｲﾁ[3]：ロボットが移動する目標位置を指定します。この場合、中間点を指します。

  • ﾅﾒﾗｶ：ロボットは目標位置に近づきますが、その位置で停止するのではなく、次の位置に向かって移動を続けます。その後の数字は、ロボットが目標位置にどれだけ近づくかを示し、数値が大きいほど目標位置から遠くなります。

このコマンドは、ロボットが関節移動の方式で撮影位置と把持のアプローチ点の間の中間点に移動することを意味します。

  • 中間点を追加することで、ロボットの移動がスムーズになり、不要な衝突を避けることができます。実際の状況に応じて複数の中間点を追加することが可能です。

  • 中間点（ｲﾁ[3]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

把持のアプローチ点に移動

 
  34:  !move to approach waypoint ;
  35:  !of picking ;
  36:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;

  • ﾁｮｸｾﾝ：ロボットが直線的に移動します。

  • ｲﾁﾚｼﾞ[60]：把持点のツール位置姿勢。

  • ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]：ロボットは把持点（ｲﾁﾚｼﾞ[60]）を基準に、指定されたｲﾁﾚｼﾞ[1]に従ってオフセットを行います。この場合、ｲﾁﾚｼﾞ[1]のZ軸の値のみを設定する必要があります。例えば、Z軸の値を-100、他の値を0に設定することで、把持点からZ軸の負方向に100mmの位置に移動します。つまり、ロボットが把持点の上方100mmの位置に移動し、把持のアプローチ点に到達します。

このコマンドはロボットが直線的に移動し、把持点の上方にある所定の位置に到達することを意味します。

アプローチ点を追加することで、ロボットが移動する際にシーンの物体（コンテナなど）と衝突するのを防ぐことができます。実際の状況に応じてｲﾁﾚｼﾞ[1]の設定を変更し、ロボットが移動する際に衝突がないことを確認してください。

把持点に移動

 
  37:  !move to picking waypoint ;
  38:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ    ;

ロボットは直線移動の方式で、把持のアプローチ点から把持点に移動します。

DO設定による把持

 
  39:  !add object grasping logic here, ;
  40:  !such as "DO[1]=ON" ;
  41:  ｲﾁｼﾞﾃｲｼ ;

ロボットが把持点に到達した後、DOコマンド（例えば「DO[1]=ON」）を設定して、ロボットハンドを制御し、ワークを把持します。実際の状況に応じてDO設定を調整する必要があります。

PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドはプログラムの実行を停止します。DO設定コマンドが設定されている場合、このPAUSEコマンドは削除できます。

把持の離れる点に移動

 
  42:  !move to departure waypoint ;
  43:  !of picking ;
  44:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;

ロボットは把持点の上方の所定位置に移動し、これを把持の離れる点と呼びます。

離れる点を追加することで、ロボットが移動する際にシーン内の物体（コンテナなど）との衝突を防ぐことができます。実際の状況に応じてｲﾁﾚｼﾞ[1]の設定を変更し、ロボットが離れる際に衝突がないことを確認してください。

中間点に移動

 
  45:  !move to intermediate waypoint ;
  46:  !of placing ;
  47:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;

ロボットは把持の離れる点と配置のアプローチ点の間の中間点に移動します。

  • 中間点を追加することで、ロボットの移動がスムーズになり、不要な衝突を避けることができます。実際の状況に応じて複数の中間点を追加することが可能です。

  • 中間点（ｲﾁ[4]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

配置のアプローチ点に移動

 
  48:  !move to approach waypoint ;
  49:  !of placing ;
  50:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;

  • ｲﾁ[5]：ロボットが移動する目標位置を指定します。この場合、配置点を指します。配置点（ｲﾁ[5]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

  • ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]：ロボットは配置点（ｲﾁ[5]）を基準に、指定されたｲﾁﾚｼﾞ[2]に従ってオフセットを適用します。ここでは、ｲﾁﾚｼﾞ[2]のZ軸の値のみを設定する必要があります。例えば、Z軸の値を-100、他の値を0に設定することで、配置点のZ軸の負方向に100mmの位置に移動します。つまり、ロボットは配置点の上方100mmの位置に移動し、配置のアプローチ点に到達します。

アプローチ点を追加することで、ロボットが移動する際にシーンの物体（コンテナなど）と衝突するのを防ぐことができます。実際の状況に応じてｲﾁﾚｼﾞ[2]の設定を変更し、ロボットが移動する際に衝突がないことを確認してください。

配置点に移動

 
  51:  !move to placing waypoint ;
  52:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ    ;

ロボットが配置のアプローチ点から配置点に移動します。

DO設定による配置

 
  53:  !add object releasing logic here, ;
  54:  !such as "DO[1]=OFF" ;
  55:  ｲﾁｼﾞﾃｲｼ ;

ロボットが配置点に到達した後、DOコマンド（例えば「DO[1]=OFF」）を設定して、ロボットハンドを制御し、ワークを配置します。実際の状況に応じてDO設定を調整する必要があります。

PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドはプログラムの実行を停止します。DO設定コマンドが設定されている場合、このPAUSEコマンドは削除できます。

配置の離れる点に移動

 
  56:  !move to departure waypoint ;
  57:  !of placing ;
  58:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;

ロボットは配置点の上方の所定位置に移動し、これを配置の離れる点と呼びます。

離れる点を追加することで、ロボットが移動する際にシーン内の物体（コンテナなど）との衝突を防ぐことができます。実際の状況に応じてｲﾁﾚｼﾞ[2]の設定を変更し、ロボットが離れる際に衝突がないことを確認してください。

Home位置に移動

 
  59:  !move back to robot home position ;
  60:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;

ロボットが配置の離れる点からHome位置に戻ります。

この情報は役に立ちましたか？

ご意見・ご要望がございましたら、以下よりお寄せください：

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。

  • Preference
  • 同意する
  • 拒否する