サンプルプログラム5：MM_S5_Viz_SetBranch
プログラム概要
機能 |
ロボットはMech-Vizプロジェクトをトリガーして実行し、Mech-Vizの分岐出口を設定します。その後、計画された経路を取得し、把持および配置を実行します。 |
||
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
||
必要なプロジェクト |
Mech-VisionとMech-Vizプロジェクト
|
||
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S5_Viz_SetBranchサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S2_Viz_Basicサンプルに比べて、Mech-Vizの分岐出口設定機能（太字部分のコード）のみが追加されています。そのため、MM_S2_Viz_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S2_Viz_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project then set branch and get ;
4: !planned path ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
10: !set current tool NO. to 1 ;
11: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
12: !move to robot home position ;
13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
18: !move to image-capturing position ;
19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
20: !trigger Mech-Viz project ;
21: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10) ;
22: !set branch, "MM_SET_BCH ;
23: !(Branch_Num,Exit_Num)" ;
24: ﾖﾋﾞﾀﾞｼ MM_SET_BCH(1,1) ;
25: !get planned path, 1st argument ;
26: !(1) means getting pose in JPs ;
27: ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
28: !check whether planned path has ;
29: !been got from Mech-Viz ;
30: !successfully ;
31: ﾓｼ ﾚｼﾞ[53]<>2100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
32: !save waypoints of the planned ;
33: !path to local variables one ;
34: !by one ;
35: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
36: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
37: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
38: !follow the planned path to pick ;
39: !move to approach waypoint ;
40: !of picking ;
41:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ ;
42: !move to picking waypoint ;
43:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ ;
44: !add object grasping logic here, ;
45: !such as "DO[1]=ON" ;
46: ｲﾁｼﾞﾃｲｼ ;
47: !move to departure waypoint ;
48: !of picking ;
49:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ ;
50: !move to intermediate waypoint ;
51: !of placing ;
52:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
53: !move to approach waypoint ;
54: !of placing ;
55:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
56: !move to placing waypoint ;
57:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ ;
58: !add object releasing logic here, ;
59: !such as "DO[1]=OFF" ;
60: ｲﾁｼﾞﾃｲｼ ;
61: !move to departure waypoint ;
62: !of placing ;
63:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
64: !move back to robot home position ;
65:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
66: ｼｭｳﾘｮｳ ;
67: ;
68: ﾗﾍﾞﾙ[99:vision error] ;
69: !add error handling logic here ;
70: !according to different ;
71: !error codes ;
72: !e.g.: status=2038 means no ;
73: !point cloud in ROI ;
74: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表はMech-Viz分岐出口設定のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 |
|---|---|
Mech-Vizの分岐ステップの出口を設定 |
このコマンドは、Mech-Vizプロジェクトが番号1の「メッセージによって異なる分岐を実行」ステップで出口0から実行を続けることを意味します。 
|