サンプルプログラム9：MM_S9_Viz_RunInAdvance
プログラム概要
機能 |
ロボットは把持時にMech-Vizプロジェクトをトリガーし、その後、分岐設定により配置時にカメラ撮影をトリガーします。これにより、次の経路を事前に計画し、サイクルタイムを短縮します。 |
||
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
||
必要なプロジェクト |
Mech-VisionとMech-Vizプロジェクト
|
||
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S9_Viz_RunInAdvanceサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S5_Viz_SetBranchサンプルに比べて、次の経路を事前に計画する機能（太字部分のコード）のみが追加されています。そのため、MM_S5_Viz_SetBranchサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S5_Viz_SetBranchサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project then set branch and get ;
4: !planned path, trigger Mech-Viz ;
5: !project and set branch in ;
6: !advance during pick&place proces ;
7: !process ;
8: !Mech-Mind, 2023-12-25 ;
9: !-------------------------------- ;
10: ;
11: !set current uframe NO. to 0 ;
12: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
13: !set current tool NO. to 1 ;
14: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
15: !move to robot home position ;
16:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
17: !initialize communication ;
18: !parameters(initialization is ;
19: !required only once) ;
20: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
21: !move to image-capturing position ;
22:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
23: !trigger Mech-Viz project ;
24: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10) ;
25: !set branch, "MM_SET_BCH ;
26: !(Branch_Num,Exit_Num)" ;
27: ﾖﾋﾞﾀﾞｼ MM_SET_BCH(1,1) ;
28: ﾗﾍﾞﾙ[1:LOOP] ;
29: !get planned path, 1st argument ;
30: !(1) means getting pose in JPs ;
31: ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
32: !check whether planned path has ;
33: !been got from Mech-Viz ;
34: !successfully ;
35: ﾓｼ ﾚｼﾞ[53]<>2100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
36: !save waypoints of the planned ;
37: !path to local variables one ;
38: !by one ;
39: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
40: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
41: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
42: !follow the planned path to pick ;
43: !move to approach waypoint ;
44: !of picking ;
45:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ ;
46: !move to picking waypoint ;
47:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ ;
48: !add object grasping logic here, ;
49: !such as "DO[1]=ON" ;
50: ｲﾁｼﾞﾃｲｼ ;
51: !trigger Mech-Viz project but not ;
52: !to trigger camera capturing ;
53: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10) ;
54: !move to departure waypoint ;
55: !of picking ;
56:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ ;
57: !move to intermediate waypoint ;
58: !of placing ;
59:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
60: !move to approach waypoint ;
61: !of placing ;
62:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
63: !set branch exit port and trigger ;
64: !camera capturing when robot ;
65: !moves out of camera’s field of ;
66: !view ;
67: ﾖﾋﾞﾀﾞｼ MM_SET_BCH(1,1) ;
68: !move to placing waypoint ;
69:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ ;
70: !add object releasing logic here, ;
71: !such as "DO[1]=OFF" ;
72: ｲﾁｼﾞﾃｲｼ ;
73: !move to departure waypoint ;
74: !of placing ;
75:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
76: !move back to robot home position ;
77:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
78: ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
79: ｼｭｳﾘｮｳ ;
80: ;
81: ﾗﾍﾞﾙ[99:vision error] ;
82: !add error handling logic here ;
83: !according to different ;
84: !error codes ;
85: !e.g.: status=2038 means no ;
86: !point cloud in ROI ;
87: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
以下は、次の経路を事前に計画するコードとその説明です。
| 処理流れ | コートと説明 | ||
|---|---|---|---|
ループで次の経路を事前に計画（把持→次の把持経路を計画→配置） |
上記のコードは、プログラムがﾗﾍﾞﾙ[1]で示すコードを繰り返し実行することを意味します。 上記のコードは、ロボットが MM_GET_VIZ コマンドを使用してMech-Vizが計画された経路を取得することを意味します。 上記のコードは、ロボットが MM_GET_JPS コマンドを使用して計画された経路を指定されたレジスタに保存することを意味します。このサンプルでは、ｲﾁﾚｼﾞ[60]、ｲﾁﾚｼﾞ[61]、ｲﾁﾚｼﾞ[62]がそれぞれ把持のアプローチ点、把持点、把持の離れる点であると仮定しています。 上記のコードは、ロボットが把持のアプローチ点、把持点、把持の離れる点の順に移動し、DOコマンド（例えばDO[1]=ON）を設定することでロボットハンドを制御し、把持を実行することを意味します。
上記のコードは、ロボットが MM_START_VIZ コマンドを使用してMech-Vizプロジェクトを再度トリガーします。この時点で、ロボットは今回計画された把持経路を取得し、把持点に移動しているため、配置が完了するのを待つことなく、事前にMech-Vizプロジェクトをトリガーして次の経路を計画することができます。
上記のコードは、ロボットが把持の離れる点（ｲﾁﾚｼﾞ[62]）、中間点（ｲﾁ[3]）、配置のアプローチ点（ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]）の順に移動することを意味します。 上記のコードは、ロボットが MM_SET_BCH コマンドを使用して「メッセージによって異なる分岐を実行」ステップの出口を設定することを意味します。この分岐出口では、「ビジョン処理による認識」ステップが実行され、Mech-Vizはビジョン認識の結果に基づいて次の把持経路を事前に計画します。 上記のコードは、ロボットが配置点（ｲﾁ[4]）に移動して配置を行い（例えばDO[1]=OFF）、その後、配置の離れる点（ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]）、Home位置の順に移動することを意味します。 |