样例程序1：MM_S1_Vis_Basic
程序解读
以下为MM_S1_Vis_Basic样例程序的代码及相关解释说明。
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project and get vision result ;
4: !Mech-Mind, 2023-12-25 ;
5: !-------------------------------- ;
6: ;
7: !set current uframe NO. to 0 ;
8: UFRAME_NUM=0 ;
9: !set current tool NO. to 1 ;
10: UTOOL_NUM=1 ;
11: !move to robot home position ;
12:J P[1] 100% FINE ;
13: !initialize communication ;
14: !parameters(initialization is ;
15: !required only once) ;
16: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
17: !move to image-capturing position ;
18:L P[2] 1000mm/sec FINE ;
19: !trigger NO.1 Mech-Vision project ;
20: CALL MM_START_VIS(1,0,2,10) ;
21: !get vision result from NO.1 ;
22: !Mech-Vision project ;
23: CALL MM_GET_VIS(1,51,53) ;
24: !check whether vision result has ;
25: !been got from Mech-Vision ;
26: !successfully ;
27: IF R[53]<>1100,JMP LBL[99] ;
28: !save first vision point data to ;
29: !local variables ;
30: CALL MM_GET_POS(1,60,70,80) ;
31: !move to intermediate waypoint ;
32: !of picking ;
33:J P[3] 50% CNT100 ;
34: !move to approach waypoint ;
35: !of picking ;
36:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
37: !move to picking waypoint ;
38:L PR[60] 300mm/sec FINE ;
39: !add object grasping logic here, ;
40: !such as "DO[1]=ON" ;
41: PAUSE ;
42: !move to departure waypoint ;
43: !of picking ;
44:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
45: !move to intermediate waypoint ;
46: !of placing ;
47:J P[4] 50% CNT100 ;
48: !move to approach waypoint ;
49: !of placing ;
50:L P[5] 1000mm/sec FINE Tool_Offset,PR[2] ;
51: !move to placing waypoint ;
52:L P[5] 300mm/sec FINE ;
53: !add object releasing logic here, ;
54: !such as "DO[1]=OFF" ;
55: PAUSE ;
56: !move to departure waypoint ;
57: !of placing ;
58:L P[5] 1000mm/sec FINE Tool_Offset,PR[2] ;
59: !move back to robot home position ;
60:J P[1] 100% FINE ;
61: END ;
62: ;
63: LBL[99:vision error] ;
64: !add error handling logic here ;
65: !according to different ;
66: !error codes ;
67: !e.g.: status=1003 means no ;
68: !point cloud in ROI ;
69: !e.g.: status=1002 means no ;
70: !vision results ;
71: PAUSE ;上述样例程序代码对应的流程如下图所示。
下表为上述程序的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。
| 流程 | 代码及说明 | ||
|---|---|---|---|
设置坐标系 |
因此，上述两条指令表示，设置当前所选的用户坐标系和工具坐标系。 |
||
移动到Home点 |
因此，整条指令表示机器人以关节角移动方式移动至示教的Home点。
|
||
初始化通信参数 |
因此，整条指令表示，机器人通过MM_INIT_SKT指令指定通信对象（工控机）的IP地址、端口号以及超时等待时间，从而与视觉系统建立连接。
|
||
移动到拍照点 |
因此，整条指令表示机器人以直线移动方式移动至示教的拍照点，速度为1000mm/sec。
|
||
触发运行Mech-Vision工程 |
因此，整条指令表示机器人触发视觉系统运行编号为1的Mech-Vision工程，且期望Mech-Vision工程返回所有视觉点。 |
||
获取视觉结果 |
因此，整条指令表示机器人获取Mech-Vision工程1返回的视觉结果。
因此，上述语句表示，当状态码R[53]为1100时，则机器人成功获取到所有视觉结果；否则视觉系统发生异常，程序跳转到LBL[99]处执行。以下为LBL[99]处的代码。 用户可根据具体异常状态码做相应的处理。此样例中对所有异常状态码做了相同处理，即通过PAUSE指令停止程序的执行。 |
||
转存视觉结果 |
因此，整条指令表示将第一个视觉点的工具位姿、标签和末端工具编号分别转存至指定寄存器。 |
||
移动到中间过渡点 |
因此，整条指令表示机器人以关节角移动方式移动至拍照点与抓取接近点之间的某个过渡点。
|
||
移动到抓取接近点 |
因此，整条指令表示机器人直线移动到抓取点上方的某处。
|
||
移动到抓取点 |
机器人以直线移动方式从抓取接近点移动到抓取点。 |
||
设置DO执行抓取 |
机器人移动到抓取点后，通过设置DO指令（例如“DO[1]=ON”），控制末端工具进行抓取。用户需根据实际场景增加设置DO的操作。
|
||
移动到抓取离开点 |
机器人移动到抓取点上方的某处，即到达抓取离开点。
|
||
移动到中间过渡点 |
机器人移动至抓取离开点与放置接近点之间的某个过渡点。
|
||
移动到放置接近点 |
|
||
移动到放置点 |
机器人从放置接近点移动到放置点。 |
||
设置DO执行放置 |
机器人移动到放置点后，通过设置DO指令（例如“DO[1]=OFF”），控制末端工具进行放置。用户需根据实际场景增加设置DO的操作。
|
||
移动到放置离开点 |
机器人移动到放置点上方的某处，即到达放置离开点。
|
||
移动到Home点 |
机器人从放置离开点重新移动到Home点。 |