样例程序9：MM_S9_Viz_RunInAdvance
程序解读
以下为MM_S9_Viz_RunInAdvance样例程序的代码及相关解释说明。
| 与MM_S5_Viz_SetBranch样例相比，本样例仅新增了提前规划下一轮路径的功能（加粗部分的代码）。因此，下文不再重复解释与MM_S5_Viz_SetBranch样例相同部分的代码（详情请参考MM_S5_Viz_SetBranch样例说明）。 |
NOP
'--------------------------------
'FUNCTION: trigger Mech-Viz
'project then set branch and get
'planned path, trigger Mech-Viz
'project and set branch in
'advance during pick&place
'process
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger Mech-Viz project
CALL JOB:MM_START_VIZ ARGF"2;30"
'set branch exit port
CALL JOB:MM_SET_BRANCH ARGF"1;1"
*LOOP
'get planned path, 1st argument
'(1) means getting pose in JPs
CALL JOB:MM_GET_VIZDATA ARGF"1;51;52;53"
'check whether planned path has
'been got from Mech-Viz
'successfully
IFTHENEXP I053<>2100
'add error handling logic here
'according to different error
'codes
'e.g.: I053=2038 means no
'point cloud in ROI
PAUSE
ENDIF
'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_JPS ARGF"1;71;61;62"
CALL JOB:MM_GET_JPS ARGF"2;72;63;64"
CALL JOB:MM_GET_JPS ARGF"3;73;65;66"
'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0
'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'trigger Mech-Viz project but not
'to trigger camera capturing
CALL JOB:MM_START_VIZ ARGF"2;30"
'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0
'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0
'set branch exit port and trigger
'camera capturing when robot
'moves out of camera’s field
'of view
CALL JOB:MM_SET_BRANCH ARGF"1;1"
'move to placing waypoint
MOVL C00004 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move back to robot home position
MOVJ C00006 VJ=50.00
JUMP *LOOP
*ENDLOOP
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
END上述样例程序代码对应的流程如下图所示。
以下为提前规划下一轮路径的代码及相关解释说明。
| 流程 | 代码及说明 | ||||||
|---|---|---|---|---|---|---|---|
通过循环（抓取→触发下一轮规划→放置）提前规划下一轮路径 |
上述代码表示，程序循环执行“*LOOP”与“JUMP *LOOP”之间的代码。 上述代码表示，机器人通过MM_GET_VIZDATA指令获取Mech-Viz规划的路径。 上述代码表示，机器人通过MM_GET_JPS指令将规划路径转存至指定变量。本样例假设P071、P072、P073分别为抓取接近点、抓取点、抓取离开点。 上述代码表示，机器人依次移动到抓取接近点、抓取点，然后设置DO指令（例如“DOUT OT#(1) ON”），控制末端工具进行抓取。 上述代码表示，机器人通过MM_START_VIZ指令再次触发Mech-Viz工程运行。此时机器人已获取到规划的抓取路径，且已移动至抓取点，因此可以提前触发Mech-Viz工程运行以规划下一轮路径，而不必等待放置完成后再触发Mech-Viz工程运行。
上述代码表示，机器人依次移动到抓取离开点（P073）、中间过渡点（C00002）、放置接近点（C00003）。
上述代码表示，机器人通过MM_SET_BRANCH指令设置“消息分支”步骤的出口。在该出口分支上，“视觉识别”步骤将被执行，Mech-Viz根据视觉识别结果提前规划下一轮抓取路径。 上述代码表示，机器人先移动到放置点（C00004），然后进行放置操作（例如“DOUT OT#(1) OFF”），然后依次移动到放置离开点（C00005）、Home点（C00006）。
当在循环代码中编写程序出错逻辑时，用户可通过“JUMP *ENDLOOP”语句以跳转到关闭通信的代码处。 |