样例程序17：MM_S17_Vis_ParseLabel

程序简介

功能说明

机器人触发Mech-Vision工程运行以获取视觉结果，接着对标签进行解析，然后根据不同标签增加不同处理流程，进而执行抓取和放置操作。

文件路径

Mech-Vision和Mech-Viz软件安装目录下Communication Component/Robot_Interface/YASKAWA/sample/MM_S17_Vis_ParseLabel。

所需工程

Mech-Vision工程（输出步骤的labels端口需要存在数据）

使用前提

已完成标准接口通信配置。
已完成自动标定。

此样例程序仅是示例程序。用户需根据实际情况在此基础上进行修改，请勿直接使用该程序。

程序解读

以下为MM_S17_Vis_ParseLabel样例程序的代码及相关解释说明。

与MM_S1_Vis_Basic样例相比，本样例仅新增了解析标签的功能（加粗部分的代码）。因此，下文不再重复解释与MM_S1_Vis_Basic样例相同部分的代码（详情请参考MM_S1_Vis_Basic样例说明）。

NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project and get vision result,
'then parse the label info
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P070 P070
SUB P071 P071
'set 100mm to z of P070
SETE P070 (3) 100000
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'get vision result from NO.1
'Mech-Vision project
CALL JOB:MM_GET_VISDATA ARGF"1;51;52"
'check whether vision result has
'been got from Mech-Vision
'successfully
IFTHENEXP I052<>1100
	'add error handling logic here
	'according to different error
	'codes
	'e.g.: I052=1003 means no point
	'cloud in ROI
	'e.g.: I052=1002 means no
	'vision result
	 PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save first vision point data to
'local variables
CALL JOB:MM_GET_POSE ARGF"1;71;61;62"
'parse label info received from
'Mech-Vision, eg. "I061=56" will
'decompose into 5 and 6
SET I064 I061
SET I065 I061
'I064=5
DIV I064 10
SET I063 I064
MUL I063 10
'I065=6
SUB I065 I063
IFTHENEXP I064=5
	'add handling logic a
	 PAUSE
ELSE
	'add handling logic b
	 PAUSE
ENDIF
'move to intermediate waypoint of
'picking
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to picking waypoint
MOVL P071 V=50.0 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to intermediate waypoint of
'placing
MOVJ C00003 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00004 V=166.6 PL=0
'move to placing waypoint
MOVL C00005 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00006 V=166.6 PL=0
'move back to robot home position
MOVJ C00007 VJ=50.00
END

上述样例程序代码对应的流程如下图所示。

下表为解析标签的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。

流程代码及说明

流程	代码及说明
解析标签	MM_GET_POSE指令可以将某个视觉点的工具位姿、标签和末端工具编号分别转存至变量P071、I61和I62变量。本样例假设I061变量值为56。 `SET I064 I061 SET I065 I061` 通过上述赋值语句后，I064和I065的变量值为56。 `'I064=5 DIV I064 10 SET I063 I064 MUL I063 10 'I065=6 SUB I065 I063` DIV I064 10：将I064整除10的商赋值给I064，则此时I064的变量值为5。 SET I063 I064：将I064赋值给I063，则此时I063的变量值为5。 MUL I063 10：将I063与10相乘（5×10），并将结果赋值给I063，则此时I063的变量值为50。 SUB I065 I063：将I065与I063相减（56-50），并将结果赋值给I065，则此时I065的变量值为6。因此，上述代码表示将I61解析成I064和I065（即56解析成5和6）。
根据解析后的标签值添加处理逻辑	`IFTHENEXP I064=5 'add handling logic a PAUSE ELSE 'add handling logic b PAUSE ENDIF` 上述代码表示，如果I064为5，则执行处理逻辑a；否则，执行处理逻辑b。用户可根据具体业务场景，针对不同的标签值，添加不同的处理逻辑。

解析标签

MM_GET_POSE指令可以将某个视觉点的工具位姿、标签和末端工具编号分别转存至变量P071、I61和I62变量。本样例假设I061变量值为56。

SET I064 I061
SET I065 I061

通过上述赋值语句后，I064和I065的变量值为56。

'I064=5
DIV I064 10
SET I063 I064
MUL I063 10
'I065=6
SUB I065 I063

DIV I064 10：将I064整除10的商赋值给I064，则此时I064的变量值为5。
SET I063 I064：将I064赋值给I063，则此时I063的变量值为5。
MUL I063 10：将I063与10相乘（5×10），并将结果赋值给I063，则此时I063的变量值为50。
SUB I065 I063：将I065与I063相减（56-50），并将结果赋值给I065，则此时I065的变量值为6。

因此，上述代码表示将I61解析成I064和I065（即56解析成5和6）。

根据解析后的标签值添加处理逻辑

IFTHENEXP I064=5
	'add handling logic a
	 PAUSE
ELSE
	'add handling logic b
	 PAUSE
ENDIF

上述代码表示，如果I064为5，则执行处理逻辑a；否则，执行处理逻辑b。用户可根据具体业务场景，针对不同的标签值，添加不同的处理逻辑。

样例程序17：MM_S17_Vis_ParseLabel

程序简介

程序解读

我们重视您的隐私