样例程序20：MM_S20_Viz_PlanAllVision

您正在查看预发布版本（V2.2.0）的文档。如果您想查阅其他版本的文档，可以点击页面右上角“切换版本”按钮进行切换。

■ 如果您不确定当前使用的产品是哪个版本，请随时联系梅卡曼德技术支持。

程序简介

功能说明

机器人先触发Mech-Viz工程运行，然后通过循环获取所有规划路径，进而通过循环进行抓取与放置操作。在本样例中，相机拍照一次，Mech-Viz会规划出全部视觉结果的抓取路径。通常用于一拍多抓的场景。

文件路径

Mech-Vision和Mech-Viz软件安装目录下Communication Component/Robot_Interface/FANUC/sample/MM_S20_Viz_PlanAllVision。

所需工程

Mech-Vision工程和Mech-Viz工程

Mech-Viz工程需满足以下配置：视觉移动步骤的复用视觉结果参数需处于勾选状态。
sample20 1

使用前提

  1. 已完成标准接口通信配置。

  2. 已完成自动标定。
此样例程序仅是示例程序。用户需根据实际情况在此基础上进行修改，请勿直接使用该程序。

程序解读

以下为MM_S20_Viz_PlanAllVision样例程序的代码及相关解释说明。

与MM_S2_Viz_Basic样例相比，本样例仅新增了通过循环获取所有规划路径并进行抓取与放置的功能（加粗部分的代码）。因此，下文不再重复解释与MM_S2_Viz_Basic样例相同部分的代码（详情请参考MM_S2_Viz_Basic样例说明）。 
   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Viz ;
   3:  !project, plan all vision results ;
   4:  !and get all planned results ;
   5:  !using command 210 ;
   6:  !Mech-Mind, 2023-12-25 ;
   7:  !-------------------------------- ;
   8:   ;
   9:  !set current uframe NO. to 0 ;
  10:  UFRAME_NUM=0 ;
  11:  !set current tool NO. to 1 ;
  12:  UTOOL_NUM=1 ;
  13:  !move to robot home position ;
  14:J P[1] 100% FINE    ;
  15:  !initialize communication ;
  16:  !parameters(initialization is ;
  17:  !required only once) ;
  18:  CALL MM_INIT_SKT('8','127.0.0.1',30000,5) ;
  19:  LBL[1:recap] ;
  20:  !move to image-capturing position ;
  21:L P[2] 1000mm/sec FINE    ;
  22:  !trigger Mech-Viz project ;
  23:  CALL MM_START_VIZ(2,10,53) ;
  24:  !check whether viz project has ;
  25:  !been triggered successfully ;
  26:  IF (R[53]<>2103 OR R[54]<>0),JMP LBL[99] ;
  27:  !get planned path ;
  28:  CALL MM_GET_PLNDT(0,3,51,52,53) ;
  29:  !check whether planned path has ;
  30:  !been got from Mech-Viz ;
  31:  !successfully ;
  32:  IF R[53]<>2100,JMP LBL[99] ;
  33:  !save all waypoint data to local ;
  34:  !variables using for-loop, a ;
  35:  !maximum of 50 points are support ;
  36:  !supported ;
  37:  FOR R[10]=1 TO R[51] ;
  38:  R[11]=59+R[10]    ;
  39:  R[12]=R[10]*30    ;
  40:  R[13]=31+R[12]    ;
  41:  R[14]=32+R[12]    ;
  42:  R[15]=33+R[12]    ;
  43:  R[16]=34+R[12]    ;
  44:  R[17]=40+R[12]    ;
  45:  CALL MM_GET_PLJOP(R[10],3,R[11],R[13],R[14],R[15],R[16],R[17]) ;
  46:  ENDFOR ;
  47:  !parse pick cycle count, here ;
  48:  !suppose 3 points per planned ;
  49:  !path ;
  50:  R[30]=R[51] DIV 3    ;
  51:  R[31]=R[51] MOD 3    ;
  52:  !check if parsed data is valid; ;
  53:  !if not, retry to get planned ;
  54:  !path or add some error handling ;
  55:  !logic ;
  56:  IF R[30]<1) OR (R[31]<>0 THEN ;
  57:  PAUSE ;
  58:  JMP LBL[1] ;
  59:  ENDIF ;
  60:  !repeatedly run pick-and-place ;
  61:  !cycle using for-loop ;
  62:  FOR R[10]=1 TO R[30] ;
  63:  R[20]=R[10]-1    ;
  64:  R[21]=R[20]*3    ;
  65:  R[31]=60+R[21]    ;
  66:  R[32]=61+R[21]    ;
  67:  R[33]=62+R[21]    ;
  68:  !move to intermediate waypoint ;
  69:  !of picking ;
  70:J P[3] 50% CNT100    ;
  71:  !follow the planned path to pick ;
  72:J PR[R[31]] 50% FINE    ;
  73:J PR[R[32]] 10% FINE    ;
  74:  !add object grasping logic here ;
  75:  PAUSE ;
  76:J PR[R[33]] 50% FINE    ;
  77:  !move to intermediate waypoint ;
  78:  !of placing ;
  79:J P[4] 50% CNT100    ;
  80:  !move to approach waypoint ;
  81:  !of placing ;
  82:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  83:  !move to placing waypoint ;
  84:L P[5] 300mm/sec FINE    ;
  85:  !add object releasing logic here, ;
  86:  !such as "DO[1]=OFF" ;
  87:  PAUSE ;
  88:  !move to departure waypoint ;
  89:  !of placing ;
  90:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  91:  !move to intermediate waypoint ;
  92:  !of placing ;
  93:J P[4] 50% CNT100    ;
  94:  ENDFOR ;
  95:  !finish pick-and-place cycle, and ;
  96:  !jump back to camera capturing ;
  97:  JMP LBL[1] ;
  98:  END ;
  99:   ;
 100:  LBL[99:vision error] ;
 101:  !add error handling logic here ;
 102:  !according to different ;
 103:  !error codes ;
 104:  !e.g.: status=2038 means no ;
 105:  !point cloud in ROI ;
 106:  !e.g.: mm_status=3099 means ;
 107:  !failed to open socket ;
 108:  PAUSE ;

上述样例程序代码对应的流程如下图所示。

sample20

下表为新增功能的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。

流程 代码及说明

获取规划路径

 
  24:  !get planned path ;
  25:  CALL MM_GET_PLNDT(0,3,51,52,53) ;

  • MM_GET_PLNDT：获取规划路径的指令。通过该指令获取的视觉移动路径点，除了包含位姿外，还将包含视觉移动规划数据或自定义数据（如有），而通过MM_GET_VIZ指令获取的视觉移动路径点将不包含视觉移动规划数据或自定义数据。

  • 0：从Mech-Viz获取规划路径。

  • 3：预期返回的数据格式，即以“位姿（关节角形式）,移动类型,末端工具编号,速度,Mech-Viz视觉移动规划数据,自定义数据项1,…,自定义数据项N”格式返回数据。

  • 51：号码为51的数值寄存器R[51]，该寄存器保存视觉系统返回的路径点个数。

  • 52：号码为52的数值寄存器R[52]，该寄存器保存视觉移动路径点（抓取点）在路径中的位置编号。

  • 53：号码为53的数值寄存器R[53]，该寄存器保存指令执行的状态码。

通过循环转存规划路径

 
  33:  !save all waypoint data to local ;
  34:  !variables using for-loop, a ;
  35:  !maximum of 50 points are support ;
  36:  !supported ;
  37:  FOR R[10]=1 TO R[51] ;
  38:  R[11]=59+R[10]    ;
  39:  R[12]=R[10]*30    ;
  40:  R[13]=31+R[12]    ;
  41:  R[14]=32+R[12]    ;
  42:  R[15]=33+R[12]    ;
  43:  R[16]=34+R[12]    ;
  44:  R[17]=40+R[12]    ;
  45:  CALL MM_GET_PLJOP(R[10],3,R[11],R[13],R[14],R[15],R[16],R[17]) ;
  46:  ENDFOR ;

  • 第34行：FOR表示以下为循环程序片段；R[10]用于控制循环的次数（即R[10]从1开始，每次循环后自增1，直到大于R[51]，结束循环）；R[51]为MM_GET_PLNDT指令中第三个参数所表示的数值寄存器，该寄存器保存视觉系统返回的路径点个数。因此，R[10]可以表示当前路径点在规划路径中的编号。

  • 第35~41行：R[11]、R[12]、R[13]、R[14]、R[15]、R[16]和R[17]分别表示当前路径点对应的关节角、移动类型、末端工具编号、速度、视觉移动规划数据和自定义数据所使用的寄存器号码。

  • 第42行：MM_GET_PLJOP指令表示将某个路径点的关节角、移动类型、末端工具编号、速度、视觉移动规划数据和自定义数据分别转存到指定寄存器中，因此整条指令表示将第R[10]编号的路径点的关节角、移动类型、末端工具编号、速度、视觉移动规划数据和自定义数据依次转存到R[11]、R[12]、R[13]、R[14]、R[15]、R[16]和R[17]所表示的寄存器中。

计算R[30]和R[31]

 
  47:  !parse pick cycle count, here ;
  48:  !suppose 3 points per planned ;
  49:  !path ;
  50:  R[30]=R[51] DIV 3    ;
  51:  R[31]=R[51] MOD 3    ;

本样例假设每次规划的抓取路径包含3个路径点，“R[51] DIV 3”表示R[51]整除3的商，“R[51] MOD 3”表示R[51]整除3的余数。R[30]表示规划的总抓取次数。如果R[31]不为0，则表示某次规划的抓取路径点个数少于3，即路径规划出现异常，需重新进行规划。

判断规划路径是否出错

 
  52:  !check if parsed data is valid; ;
  53:  !if not, retry to get planned ;
  54:  !path or add some error handling ;
  55:  !logic ;
  56:  IF ((R[30]<1) OR (R[31]<>0)) THEN ;
  57:  PAUSE ;
  58:  JMP LBL[1] ;
  59:  ENDIF ;

如果抓取次数R[30]小于1，或R[31]不为0，则表示路径规划出现异常，用户需在此处添加处理逻辑，例如重新触发Mech-Viz工程并获取规划路径。

通过循环进行抓取和放置

 
  60:  !repeatedly run pick-and-place ;
  61:  !cycle using for-loop ;
  62:  FOR R[10]=1 TO R[30] ;
  63:  R[20]=R[10]-1    ;
  64:  R[21]=R[20]*3    ;
  65:  R[31]=60+R[21]    ;
  66:  R[32]=61+R[21]    ;
  67:  R[33]=62+R[21]    ;
  68:  !move to intermediate waypoint ;
  69:  !of picking ;
  70:J P[3] 50% CNT100    ;
  71:  !follow the planned path to pick ;
  72:J PR[R[31]] 50% FINE    ;
  73:J PR[R[32]] 10% FINE    ;
  74:  !add object grasping logic here ;
  75:  PAUSE ;
  76:J PR[R[33]] 50% FINE    ;
  77:  !move to intermediate waypoint ;
  78:  !of placing ;
  79:J P[4] 50% CNT100    ;
  80:  !move to approach waypoint ;
  81:  !of placing ;
  82:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  83:  !move to placing waypoint ;
  84:L P[5] 300mm/sec FINE    ;
  85:  !add object releasing logic here, ;
  86:  !such as "DO[1]=OFF" ;
  87:  PAUSE ;
  88:  !move to departure waypoint ;
  89:  !of placing ;
  90:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  91:  !move to intermediate waypoint ;
  92:  !of placing ;
  93:J P[4] 50% CNT100    ;
  94:  ENDFOR ;

上述代码表示，在FOR循环中，机器人移动到每次规划的3个路径点，从而完成抓取操作，然后接着执行放置操作。R[10]用于控制循环的次数，即R[10]从1开始，每次循环后自增1，直到大于抓取次数R[30]，结束循环。每当R[10]增加1，则R[21]增加3，60+R[21] ~ 62+R[21]（即R[31] ~ R[33]）表示每次规划的3个路径点将要存放的3个寄存器号码。

该页面是否有帮助？

可以通过以下方式反馈意见：

我们重视您的隐私

我们使用 cookie 为您在我们的网站上提供最佳体验。继续使用该网站即表示您同意使用 cookie。如果您拒绝，将使用一个单独的 cookie 来确保您在访问本网站时不会被跟踪或记住。

  • Preference
  • 同意
  • 不同意