샘플 프로그램9: MM_S9_Viz_RunInAdvance
프로그램 소개
기능 설명 |
로봇이 물체를 피킹할 때 Mech-Viz프로젝트를 트리거하고 메시지 분기를 통해 배치할 때 카메라 이미지 캡처를 트리거합니다. 이를 통해 다음 경로를 미리 계획하여 사이클 타임을 단축할 수 있습니다. |
||
파일 경로 |
Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 |
||
필요한 프로젝트 |
Mech-Vision와 Mech-Viz 프로젝트
|
||
사용 조건 |
|
| 이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오. |
프로그램 설명
다음에는 MM_S9_Viz_RunInAdvance 샘플 프로그램의 코드와 관련 설명입니다.
| MM_S5_Viz_SetBranch 샘플과 비하면, 이 샘플은 다음 경로를 미리 계획할 수 있는 기능만 추가되었습니다.(이 기능의 코드가 굵게 표시됨). 따라서, 아래 부분에서는 다음 경로를 미리 계획하는 기능만 설명됩니다. (MM_S9_Viz_RunInAdvance의 MM_S5_Viz_SetBranch과 일치하는 부분에 대한 정보는 MM_S5_Viz_SetBranch 샘플 프로그램 설명을 참조하십시오). |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project then set branch and get ;
4: !planned path, trigger Mech-Viz ;
5: !project and set branch in ;
6: !advance during pick&place proces ;
7: !process ;
8: !Mech-Mind, 2023-12-25 ;
9: !-------------------------------- ;
10: ;
11: !set current uframe NO. to 0 ;
12: UFRAME_NUM=0 ;
13: !set current tool NO. to 1 ;
14: UTOOL_NUM=1 ;
15: !move to robot home position ;
16:J P[1] 100% FINE ;
17: !initialize communication ;
18: !parameters(initialization is ;
19: !required only once) ;
20: CALL MM_INIT_SKT('8','127.0.0.1',30000,5) ;
21: !move to image-capturing position ;
22:L P[2] 1000mm/sec FINE ;
23: !trigger Mech-Viz project ;
24: CALL MM_START_VIZ(2,10,53) ;
25: !check whether viz project has ;
26: !been triggered successfully ;
27: IF (R[53]<>2103),JMP LBL[99] ;
28: !set branch, "MM_SET_BCH ;
29: !(Branch_Num,Exit_Num)" ;
30: CALL MM_SET_BCH(1,1,53) ;
31: !check whether viz branch has ;
32: !been set successfully ;
33: IF (R[53]<>2105),JMP LBL[99] ;
34: LBL[1:LOOP] ;
35: !get planned path, 1st argument ;
36: !(1) means getting pose in JPs ;
37: CALL MM_GET_VIZ(1,51,52,53) ;
38: !check whether planned path has ;
39: !been got from Mech-Viz ;
40: !successfully ;
41: IF (R[53]<>2100),JMP LBL[99] ;
42: !save waypoints of the planned ;
43: !path to local variables one ;
44: !by one ;
45: CALL MM_GET_JPS(1,60,70,80) ;
46: CALL MM_GET_JPS(2,61,71,81) ;
47: CALL MM_GET_JPS(3,62,72,82) ;
48: !follow the planned path to pick ;
49: !move to approach waypoint ;
50: !of picking ;
51:J PR[60] 50% FINE ;
52: !move to picking waypoint ;
53:J PR[61] 10% FINE ;
54: !add object grasping logic here, ;
55: !such as "DO[1]=ON" ;
56: PAUSE ;
57: !trigger Mech-Viz project but not ;
58: !to trigger camera capturing ;
59: CALL MM_START_VIZ(2,10,53) ;
60: !check whether viz project has ;
61: !been triggered successfully ;
62: IF (R[53]<>2103),JMP LBL[99] ;
63: !move to departure waypoint ;
64: !of picking ;
65:J PR[62] 50% FINE ;
66: !move to intermediate waypoint ;
67: !of placing ;
68:J P[3] 50% CNT100 ;
69: !move to approach waypoint ;
70: !of placing ;
71:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
72: !set branch exit port and trigger ;
73: !camera capturing when robot ;
74: !moves out of camera’s field of ;
75: !view ;
76: CALL MM_SET_BCH(1,1,53) ;
77: !check whether viz branch has ;
78: !been set successfully ;
79: IF (R[53]<>2105),JMP LBL[99] ;
80: !move to placing waypoint ;
81:L P[4] 300mm/sec FINE ;
82: !add object releasing logic here, ;
83: !such as "DO[1]=OFF" ;
84: PAUSE ;
85: !move to departure waypoint ;
86: !of placing ;
87:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
88: !move back to robot home position ;
89:J P[1] 100% FINE ;
90: JMP LBL[1] ;
91: END ;
92: ;
93: LBL[99:vision error] ;
94: !add error handling logic here ;
95: !according to different ;
96: !error codes ;
97: !e.g.: status=2038 means no ;
98: !point cloud in ROI ;
99: !e.g.: status=3099 means ;
100: !failed to open socket ;
101: PAUSE ;위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.
아래는 다음 경로를 미리 계획하는 코드와 관련된 설명입니다.
| 워크플로 | 코드와 설명 | ||
|---|---|---|---|
루프(피킹→다음 경로 계획을 트리거하기→배치)를 통해 다음 경로를 미리 계획하기 |
위의 코드는 프로그램은 LBL[1] 위치의 코드를 순환하게 수행합니다. 위 코드는 로봇이 MM_GET_VIZ 명령어를 통해 Mech-Viz가 계획한 경로를 획득함을 나타냅니다. 위 코드는 로봇이 MM_GET_JPS 명령어를 통해 계획된 경로를 지정된 레지스터에 저장함을 나타냅니다. 이 샘플에서는 R[60], PR[61], PR[62]가 각각 피킹 접근 웨이포인트, 피킹 웨이포인트, 피킹 출발 웨이포인트로 설정됩니다. 위 코드는 로봇이 순차적으로 피킹 접근 웨이포인트와 피킹 웨이포인트로 이동한 후, DO 명령어(예: DO[1]=ON)를 설정하여 말단 장치를 제어하여 피킹를 수행하는 것을 나타냅니다.
위 코드는 로봇이 MM_START_VIZ명령어를 통해 Mech-Viz 프로젝트를 다시 트리거함을 나타냅니다. 이제 로봇은 이번 계획된 피킹 경로를 획득하고 피킹 웨이포인트로 이동했으므로 배치 완료를 기다릴 필요 없이 Mech-Viz 프로젝트 실행을 미리 트리거하여 다음 경로 계획을 할 수 있습니다.
위 코드는 로봇이 순차적으로 피킹 출발 웨이포인트(PR[62]), 중간 웨이포인트(P[3]), 그리고 배치 접근 웨이포인트(Tool_Offset,PR[2])으로 이동하는 것을 나타냅니다. 위 코드는 로봇이 MM_SET_BCH 명령어를 통해 "메시지 분기" 스텝의 아웃 포트를 설정함을 나타냅니다. 이 아웃 포트 분기에서 "비전 인식" 스텝이 실행되며, Mech-Viz는 비전 인식 결과에 따라 다음 피킹 경로를 미리 계획합니다. 위 코드는 로봇이 먼저 배치 웨이포인트(P[4])로 이동한 후, 배치 작업(예: DO[1]=OFF)을 수행하고, 그 후 배치 출발 웨이포인트(Tool_Offset,PR[2]과 Home 포인트로 순차적으로 이동하는 것을 나타냅니다. |