샘플 프로그램18: MM_S18_Viz_GetUserData
프로그램 소개
기능 설명 |
로봇은 피킹 경로를 얻을 때 동시에 Mech-Vision 프로젝트에서 출력된 사용자 정의 데이터를 획득합니다. |
파일 경로 |
Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 |
필요한 프로젝트 |
Mech-Vision 프로젝트 (하나 이상의 사용자 정의 포트를 출력 스텝에 추가해야 합니다) 및 Mech-Viz 프로젝트 (말단장치 유형은 디팔레타이징 진공 그리퍼입니다). |
사용 전제 조건 |
|
| 이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오. |
프로그램 설명
다음에는 MM_S18_Viz_GetUserData 샘플 프로그램의 코드와 관련 설명입니다.
| MM_S15_Viz_GetDoList 샘플과 비하면, 이 샘플은 아래와 같이 굵게 표시된 코드 부분만 수정되었습니다. 따라서, MM_S18_Viz_GetUserData의 MM_S15_Viz_GetDoList과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S15_Viz_GetDoList 샘플 프로그램 설명을 참조하십시오). |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project, then get planned path ;
4: !and get custom data from ;
5: !Mech-Vision using command 210 ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: UFRAME_NUM=0 ;
11: !set current tool NO. to 1 ;
12: UTOOL_NUM=1 ;
13: !move to robot home position ;
14:J P[1] 100% FINE ;
15: !initialize communication ;
16: !parameters(initialization is ;
17: !required only once) ;
18: CALL MM_INIT_SKT('8','127.0.0.1',30000,5) ;
19: !move to image-capturing position ;
20:L P[2] 1000mm/sec FINE ;
21: !trigger Mech-Viz project ;
22: CALL MM_START_VIZ(2,10,53) ;
23: !check whether viz project has ;
24: !been triggered successfully ;
25: IF (R[53]<>2103),JMP LBL[99] ;
26: !get planned path ;
27: CALL MM_GET_PLNDT(0,3,51,52,53) ;
28: !check whether planned path has ;
29: !been got from Mech-Viz ;
30: !successfully ;
31: IF R[53]<>2100,JMP LBL[99] ;
32: !get gripper control signal list ;
33: CALL MM_GET_DL(0,0,53) ;
34: !check whether viz DoList has ;
35: !been gotten successfully ;
36: IF (R[53]<>2102),JMP LBL[99] ;
37: !save waypoints of the planned ;
38: !path to local variables one ;
39: !by one ;
40: CALL MM_GET_PLJOP(1,3,60,61,62,63,64,70) ;
41: CALL MM_GET_PLJOP(2,3,61,91,92,93,94,100) ;
42: CALL MM_GET_PLJOP(3,3,62,121,122,123,124,130) ;
43: !save received custom data of ;
44: !2nd point ;
45: R[10]=R[94] ;
46: R[11]=R[95] ;
47: R[12]=R[96] ;
48: !follow the planned path to pick ;
49: !move to approach waypoint ;
50: !of picking ;
51:J PR[60] 50% FINE ;
52: !move to picking waypoint ;
53:J PR[61] 10% FINE ;
54: !add object grasping logic here ;
55: PAUSE ;
56: !set gripper control signal ;
57: CALL MM_SET_DL(0) ;
58: !move to departure waypoint ;
59: !of picking ;
60:J PR[62] 50% FINE ;
61: !move to intermediate waypoint ;
62: !of placing ;
63:J P[3] 50% CNT100 ;
64: !move to approach waypoint ;
65: !of placing ;
66:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
67: !move to placing waypoint ;
68:L P[4] 300mm/sec FINE ;
69: !add object releasing logic here, ;
70: !such as "DO[1]=OFF" ;
71: PAUSE ;
72: !move to departure waypoint ;
73: !of placing ;
74:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
75: !move back to robot home position ;
76:J P[1] 100% FINE ;
77: END ;
78: ;
79: LBL[99:vision error] ;
80: !add error handling logic here ;
81: !according to different ;
82: !error codes ;
83: !e.g.: status=2038 means no ;
84: !point cloud in ROI ;
85: !e.g.: mm_status=3099 means ;
86: !failed to open socket ;
87: PAUSE ;위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.
아래 표는 새롭게 추가된 코드의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.
| 워크플로 | 코드와 설명 | ||||
|---|---|---|---|---|---|
웨이포인트의 사용자 정의 데이터를 저장하기 |
로봇은 MM_GET_PLNDT 명령어를 실행하여 웨이포인트의 비전 이동 계획 결과와 사용자 정의 데이터를 얻고, 그 후 MM_GET_PLJOP 명령어를 실행하여 로봇 메모리에 저장된 웨이포인트의 비전 이동 계획 결과와 사용자 정의 데이터를 지정된 레지스터에 저장합니다. 이 샘플에서는 피킹 웨이포인트(PR[61])의 사용자 정의 데이터가 R[94]부터 시작하는 레지스터에 순서대로 저장합니다. 위 코드는 비전 이동 웨이포인트(피킹 웨이포인트)의 세 가지 사용자 정의 데이터R[94], R[95], R[96]를 각각 R[10], R[11], R[12]로 할당하는 것을 나타냅니다.
|