샘플 프로그램15: MM_S15_Viz_GetDoList
프로그램 소개
기능 설명 |
로봇은 피킹 경로와 DO 신호를 획득한 후, 피킹 웨이포인트로 이동하고 DO 신호를 설정하여 피킹 및 배치 작업을 완성합니다. 이 샘플 예시는 일반적으로 디팔레타이징 시나리오에 사용되며, 로봇의 말단장치는 멀티 파티션 빨판입니다. |
파일 경로 |
Mech-Vision 및 Mech-Viz의 설치 디렉터리로 이동하여 |
필요한 프로젝트 |
Mech-Vision와 Mech-Viz 프로젝트(말단장치 유형은 디팔레타이징 진공 그리퍼입니다) |
사용 전제 조건 |
|
| 이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오. |
프로그램 설명
다음에는 MM_S15_Viz_GetDoList 샘플 프로그램의 코드와 관련 설명입니다.
| MM_S2_Viz_Basic 샘플과 비하면, 이 샘플은 아래와 같이 굵게 표시된 코드 부분만 수정되었습니다. 따라서 MM_S2_Viz_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S2_Viz_Basic 샘플 프로그램 설명을 참조하십시오). |
NOP
'--------------------------------
'FUNCTION: trigger Mech-Viz
'project, then get planned path
'and gripper control signal using
'command 210
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger Mech-Viz project
CALL JOB:MM_START_VIZ ARGF"2;30;80"
IFTHENEXP I080<>2103
'add error handling logic here
PAUSE
ENDIF
'get planned path
CALL JOB:MM_GET_PLANDATA ARGF"0;3;51;52;53"
'check whether planned path has
'been got from Mech-Viz
'successfully
IFTHENEXP I053<>2100
'add error handling logic here
'according to different error
'codes
'e.g.: I053=2038 means no
'point cloud in ROI
PAUSE
ENDIF
'get gripper control signal list
CALL JOB:MM_GET_DOLIST ARGF"0;0;80"
IFTHENEXP I080<>2102
'add error handling logic here
PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_PLANPOSE ARGF"1;71;61;31"
CALL JOB:MM_GET_PLANPOSE ARGF"2;72;71;31"
CALL JOB:MM_GET_PLANPOSE ARGF"3;73;81;31"
'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0
'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0
'set gripper control signal when
'current waypoint is picking
'waypoint
CALL JOB:MM_SET_DOLIST ARGF"0"
PAUSE
'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0
'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0
'move to placing waypoint
MOVL C00004 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move back to robot home position
MOVJ C00006 VJ=50.00
END위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.
아래 표는 굵게 표시된 코드의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.
| 워크플로 | 코드와 설명 | ||
|---|---|---|---|
계획 경로를 획득하기 |
|
||
진공 그리퍼의 DO 신호를 가져오기 |
따라서, 위의 문장은 상태 코드 I080가 2102일 경우 로봇이 진공 그리퍼 DO 신호를 성공적으로 획득했다는 것을 의미하며, 그렇지 않으면 비전 시스템에 이상이 발생한 것이며, 프로그램은 IFTHENEXP와 ENDIF 사이의 코드를 실행합니다. 사용자는 구체적인 비정상 상태 코드에 따라 적절한 처리를 수행할 수 있습니다. 이 샘플에서는 모든 비정상적인 상태 코드에 대해 같은 처리를 수행하며, 즉 PAUSE 명령어를 사용하여 프로그램 실행을 일시 중단합니다. |
||
계획 경로를 저장하기 |
따라서, “CALL JOB:MM_GET_PLANPOSE ARGF"1;71;61;31"”는 첫 번째 웨이포인트의 포즈, 이동 유형, 말단장치 번호, 속도, 비전 이동 계획 데이터 및 사용자 정의 데이터를 지정된 변수에 저장하는 명령어입니다.
|
||
피킹 웨이포인트로 이동하고 피킹하기 |
따라서 위 문장은 로봇이 피킹 웨이포인트(P072)로 이동한 후, MM_SET_DOLIST명령어를 통해 진공 그리퍼의 DO 신호를 설정하여 피킹 작업을 완료합니다. |