Example Program 5: MM_S5_Viz_SetBranch

Program Introduction

Description

The robot triggers the Mech-Viz project to run, sets the exit port for the Branch by Msg Step in the Mech-Viz project, and then obtains the planned path for picking and placing.

File path

You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the Communication Component/Robot_Interface/YASKAWA/sample/MM_S5_Viz_SetBranch path.

Project

Mech-Vision and Mech-Viz projects

The Branch by Msg Step of the Mech-Viz project needs to be configured beforehand.

Prerequisites

You have set up the Standard Interface communication.
Automatic calibration is completed.

This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario.

Program Description

This part describes the MM_S5_Viz_SetBranch example program.

The only difference between the MM_S5_Viz_SetBranch example program and the MM_S2_Viz_Basic example program is that MM_S5_Viz_SetBranch can set the exit port of the Branch by Msg Step in the Mech-Viz project (this code of this feature is bolded). As such, only the feature of setting the exit port of the Branch by Msg Step is described in the following section. For information about the parts of MM_S5_Viz_SetBranch that are consistent with those of MM_S2_Viz_Basic, see Example Program 2: MM_S2_Viz_Basic.

NOP
'--------------------------------
'FUNCTION: trigger Mech-Viz
'project then set branch and get
'planned path
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger Mech-Viz project
CALL JOB:MM_START_VIZ ARGF"2;30"
'set branch
CALL JOB:MM_SET_BRANCH ARGF"1;1"
'get planned path, 1st argument
'(1) means getting pose in JPs
CALL JOB:MM_GET_VIZDATA ARGF"1;51;52;53"
'check whether planned path has
'been got from Mech-Viz
'successfully
IFTHENEXP I053<>2100
	'add error handling logic here
	'according to different error
	'codes
	'e.g.: I053=2038 means no
	'point cloud in ROI
	 PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_JPS ARGF"1;71;61;62"
CALL JOB:MM_GET_JPS ARGF"2;72;63;64"
CALL JOB:MM_GET_JPS ARGF"3;73;65;66"
'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0
'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0
'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0
'move to placing waypoint
MOVL C00004 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move back to robot home position
MOVJ C00006 VJ=50.00
END

The workflow corresponding to the above example program code is shown in the figure below.

The table below describes the process of setting the exit port of the Branch by Msg Step in the Mech-Viz project. You can click the hyperlink to the command name to view its detailed description.

Feature Code and description

Feature	Code and description
Set the exit port for the Branch by Msg Step in Mech-Viz	`'set branch CALL JOB:MM_SET_BRANCH ARGF"1;1"` MM_SET_BRANCH: The command to set the exit port for the Branch by Msg Step in Mech-Viz. First 1: The Step ID of the Branch by Msg Step. Second 1: The Mech-Viz project takes exit port 0 of the Branch by Msg Step. Note that if this parameter is set to N, the exit port is N-1. In the entire statement, the Mech-Viz project with an ID of 1 takes the port 0 of the Branch by Msg Step, as shown in the following figure.

Set the exit port for the Branch by Msg Step in Mech-Viz

'set branch
CALL JOB:MM_SET_BRANCH ARGF"1;1"

MM_SET_BRANCH: The command to set the exit port for the Branch by Msg Step in Mech-Viz.
First 1: The Step ID of the Branch by Msg Step.
Second 1: The Mech-Viz project takes exit port 0 of the Branch by Msg Step. Note that if this parameter is set to N, the exit port is N-1.

In the entire statement, the Mech-Viz project with an ID of 1 takes the port 0 of the Branch by Msg Step, as shown in the following figure.

Example Program 5: MM_S5_Viz_SetBranch

Program Introduction

Program Description

We Value Your Privacy