Example Program 1: MM_S1_Vis_Basic

You are currently viewing the documentation for version 2.0.0. To access documentation for other versions, click the "Switch Version" button located in the upper-right corner of the page.

■ To use the latest version, visit the Mech-Mind Download Center to download it.

■ If you're unsure about the version of the product you are using, please contact Mech-Mind Technical Support for assistance.

Program Introduction

Description

The robot triggers the Mech-Vision project to run, and then obtains the vision result for picking and placing the object.

File path

You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the Communication Component/Robot_Interface/ABB/sample/MM_S1_Vis_Basic path.

For RobotWare6, the file extension is .mod. For RobotWare7, please modify the file extension from .mod to .modx.

Project

Mech-Vision project

Prerequisites

  1. You have set up the standard interface communication.

  2. Automatic calibration is completed.
This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario.

Program Description

This part describes the MM_S1_Vis_Basic example program.

MODULE MM_S1_Vis_Basic
!--------------------------------------------------------------
! FUNCTION: trigger Mech-Vision project and get vision result
! Mech-Mind, 2023-12-25
!-------------------------------------------------------------
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num toolid:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[500,100,300],[0.00226227,-0.99991,-0.00439596,0.0124994],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

PROC Sample_1()
    !set the acceleration parameters
    AccSet 50, 50;
    !set the velocity parameters
    VelSet 50, 1000;
    !move to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
    !initialize communication parameters (initialization is required only once)
    MM_Init_Socket "127.0.0.1",50000,300;
    !move to image-capturing position
    MoveL camera_capture,v1000,fine,gripper1;
    !open socket connection
    MM_Open_Socket;
    !trigger NO.1 Mech-Vision project
    MM_Start_Vis 1,0,2,snap_jps;
    !get vision result from NO.1 Mech-Vision project 
    MM_Get_VisData 1,pose_num,status;
    !check whether vision result has been got from Mech-Vision successfully
    IF status<>1100 THEN
        !add error handling logic here according to different error codess
        !e.g.: status=1003 means no point cloud in ROI
        !e.g.: status=1002 means no vision result
        Stop;
    ENDIF
    !close socket connection
    MM_Close_Socket;
    !save first vision point data to local variables
    MM_Get_Pose 1,pickpoint,label,toolid;
    !move to intermediate waypoint of picking
    MoveJ pick_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to picking waypoint
    MoveL pickpoint,v300,fine,gripper1;
    !add object grasping logic here, such as "setdo DO_1, 1;"
    Stop;
    !move to departure waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to intermediate waypoint of placing
    MoveJ drop_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move to placing waypoint
    MoveL drop,v300,fine,gripper1;
    !add object releasing logic here, such as "setdo DO_1, 0;"
    Stop;
    !move to departure waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move back to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
ENDPROC
ENDMODULE

The workflow corresponding to the above example program code is shown in the figure below.

sample1

The table below explains the above program. You can click the hyperlink to the command name to view its detailed description.

Feature Code and description

Define variables

 
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num toolid:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[500,100,300],[0.00226227,-0.99991,-0.00439596,0.0124994],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

Define local variables. The above local variables are only valid in this program.

Teach the home position (home variable), the pose of the input Mech-Vision project (snap_jps variable), the image-capturing position (camera_capture variable), the intermediate waypoint of picking (pick_waypoint variable), the intermediate waypoint of placing (drop_waypoint variable), and the placing waypoint (drop variable), and set the tool data (gripper1 variable) in advance.

For information about how to teach a waypoint, see the Teach Calibration Start Point section in the calibration document.

Set the acceleration and velocity

 
!set the acceleration parameters
AccSet 50, 50;
!set the velocity parameters
VelSet 50, 1000;

AccSet 50, 50: Limit the acceleration to 50% of the normal value and the acceleration rate to 50% of the normal value.

VelSet 50, 1000: Set the velocity to 50% of the programmed rate and the maximum TCP rate to 1000 mm/s.

Move to the home position

 
!move to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;

  • MoveAbsJ: The absolute position motion command of the ABB robot, indicating that each joint axis of the robot moves to a specified position independently.

  • home: Specify the target position to which the robot moves, i.e., the home position that is taught. The home position is usually a safe one where the robot is away from objects and the surrounding equipment.

  • \NoEOffs: Specify that the motion is not affected by external axes.

  • v3000: Specify that the robot velocity is 3000 mm/s.

  • fine: Move the robot to the specified position.

  • gripper1: Specify the ID of the tool used by the robot when it moves.

The entire command indicates that the robot moves to the taught home position without the impact of external axes at a velocity of 3000 mm/s.

Initialize communication parameters

 
!initialize communication parameters (initialization is required only once)
MM_Init_Socket "127.0.0.1",50000,300;

The robot sends the MM_Init_Socket command to set the IP address, port number, and timeout period of the communication object (the IPC) to 127.0.0.1, 50000, and 300 seconds.

Please modify the IP address and port number of the IPC according to the actual situation. The IP address and port number must be consistent with those set in the vision system.

Move to the image-capturing position

 
!move to image-capturing position
MoveL camera_capture,v1000,fine,gripper1;

  • MoveL: The linear motion command of the ABB robot. This command specifies to move the robot along a linear path to a specified position.

  • camera_capture: Specify the target position to which the robot moves, i.e., the image-capturing position that is taught. The image-capturing position refers to the position of the robot where the camera on the robot captures images. At this position, the robot arm should not block the camera’s FOV.

The entire command indicates that the robot moves to the taught image-capturing position accurately in linear motion, with a velocity of 1000 mm/s.

Establish the communication

 
!open socket connection
MM_Open_Socket;

The TCP communication between the robot and the vision system is established by using the MM_Open_Socket command.

Trigger the Mech-Vision project to run

 
!trigger NO.1 Mech-Vision project
MM_Start_Vis 1,0,2,snap_jps;

  • MM_Start_Vis: The command to trigger the Mech-Vision project to run.

  • 1: The Mech-Vision project ID.

  • 0: The Mech-Vision project is expected to return all vision points.

  • 2: Specify that the robot flange pose must be input to the Mech-Vision project.

  • snap_jps: Custom joint positions. The joint positions in this example program are of no practical use but must be set.

The entire statement indicates that the robot triggers the vision system to run the Mech-Vision project with an ID of 1 and expects the Mech-Vision project to return all vision points.

Get the vision result

 
!get vision result from NO.1 Mech-Vision project
MM_Get_VisData 1,pose_num,status;

  • MM_Get_VisData: The command to obtain the vision result.

  • 1: The Mech-Vision project ID.

  • pose_num: The variable that stores the number of received vision points.

  • status: The variable that stores the command execution status code.

The entire statement indicates that the robot obtains the vision result from the Mech-Vision project with an ID of 1.

The returned vision result is saved to the robot memory and cannot be directly obtained. To access the vision result, you must store the vision result in a subsequent step. 
!check whether vision result has been got from Mech-Vision successfully
IF status<>1100 THEN
    !add error handling logic here according to different error codess
    !e.g.: status=1003 means no point cloud in ROI
    !e.g.: status=1002 means no vision result
    Stop;
ENDIF

When the status code is 1100, the robot has successfully obtained all vision result. Otherwise, an error has occurred in the vision system. You can perform the corresponding operation based on the specific error code.

Close the communication

 
!close socket connection
MM_Close_Socket;

The TCP communication between the robot and the vision system is closed by using the MM_Close_Socket command.

Store the vision result

 
!save first vision point data to local variables
MM_Get_Pose 1,pickpoint,label,toolid;

  • MM_Get_Pose: The command to store the vision result.

  • 1: The first vision point is stored.

  • pickpoint: The variable that stores the TCP of the first vision point, which is the TCP of the picking point.

  • label: The variable that stores the label corresponding to the first vision point.

  • toolid: The variable that stores the tool ID corresponding to the first vision point.

The entire statement stores the TCP, label, and tool ID of the first vision point in the specified variables.

Move to the intermediate waypoint

 
!move to intermediate waypoint of picking
MoveJ pick_waypoint,v1000,z50,gripper1;

  • MoveJ: The joint position motion command of the ABB robot, indicating that the robot moves along the arc to a specified position.

  • pick_waypoint: Specify the target position to which the robot moves, i.e., the intermediate waypoint.

  • z50: The blend radius is 50 mm.

The entire command moves the robot in joint positions to a certain intermediate waypoint between the image-capturing position and the approach waypoint of picking, with a velocity of 1000 mm/s and a blend radius of 50 mm.

Adding intermediate waypoints can ensure smooth robot motion and avoid unnecessary collisions. You can add multiple intermediate waypoints according to the actual situation.

Move to the approach waypoint of picking

 
!move to approach waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;

  • MoveL: The motion command of the ABB robot. This command specifies to move the robot along a linear path.

  • RelTool(pickpoint,0,0,-100): Specify the target position of the robot, where RelTool stands for the movement relative to the tool reference frame, pickpoint is the base point in the tool reference frame, and 0,0,-100 stands for 100 mm relative to the negative Z-direction of pickpoint (i.e., the robot moves to 100 mm above the picking waypoint to reach the approach waypoint of picking).

The entire command indicates that the robot moves linearly to 100 mm above the picking waypoint at a velocity of 1000 mm/s.

Adding approach waypoints of picking can prevent the robot from colliding with objects (such as bins) in the scene when moving. You can modify the Z-axis negative offset based on the actual scenario to ensure that no collision occurs during the approaching process.

Move to the picking waypoint

 
!move to picking waypoint
MoveL pickpoint,v300,fine,gripper1;

The robot moves from the approach waypoint of picking to the picking waypoint in linear motion.

Set DO commands to perform picking

 
!add object grasping logic here, such as "setdo DO_1, 1;"
Stop;

After the robot moves to the picking waypoint, you can set a DO command (such as setdo DO_1, 1;) to control the robot to use the tool to perform picking. Please set DO commands based on the actual situation.

Stop indicates that program execution is paused. If you have added a statement to set a DO command, you can delete the Stop statement here.

Move to the departure waypoint of picking

 
!move to departure waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;

The robot moves to 100 mm above the picking waypoint and reaches the departure waypoint of picking.

Adding departure waypoints of picking can prevent the robot from colliding with objects (such as bins) in the scene when moving. You can modify the Z-axis negative offset based on the actual scenario to ensure that no collision occurs during the departing process.

Move to the intermediate waypoint

 
!move to intermediate waypoint of placing
MoveJ drop_waypoint,v1000,z50,gripper1;

The robot moves to a intermediate waypoint between the departure waypoint of picking and the approach waypoint of placing.

Adding intermediate waypoints can ensure smooth robot motion and avoid unnecessary collisions. You can add multiple intermediate waypoints according to the actual situation.

Move the robot to the approach waypoint of placing

 
!move to approach waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;

The robot moves to 100 mm above the placing waypoint and reaches the approach waypoint of placing.

Adding approach waypoints of placing can prevent the robot from colliding with objects (such as bins) in the scene when moving. You can modify the Z-axis negative offset based on the actual scenario to ensure that no collision occurs during the approaching process.

Move to the placing waypoint

 
!move to placing waypoint
MoveL drop,v300,fine,gripper1;

The robot moves from the approach waypoint of placing to the placing waypoint.

Set DO commands to perform placing

 
!add object releasing logic here, such as "setdo DO_1, 0;"
Stop;

After the robot moves to the placing waypoint, you can set a DO command (such as setdo DO_1, 0;) to control the robot to use the tool to perform placing. Please set DO commands based on the actual situation.

Stop indicates that program execution is paused. If you have added a statement to set a DO command, you can delete the Stop statement here.

Move the robot to the departure waypoint of placing

 
!move to departure waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;

The robot moves to 100 mm above the placing waypoint and reaches the departure waypoint of placing.

Adding departure waypoints of placing can prevent the robot from colliding with objects (such as bins) in the scene when moving. You can modify the Z-axis negative offset based on the actual scenario to ensure that no collision occurs during the departing process.

Move to the home position

 
!move back to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;

The robot moves from the departure waypoint of placing to the home waypoint again.

We Value Your Privacy

We use cookies to provide you with the best possible experience on our website. By continuing to use the site, you acknowledge that you agree to the use of cookies. If you decline, a single cookie will be used to ensure you're not tracked or remembered when you visit this website.

  • Preference
  • I accept
  • I don't accept