픽 앤 플레이스 실현

&ACCESS RVO
DEF MM_S3_Vis_Path ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Vision project and get
; planned path
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
Init:
   ;move to robot home position
   PTP HOME Vel=100 % DEFAULT
   $OUT[131] = True
   $OUT[132] = False
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
   ;move to image-capturing position
   LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger Mech-Vision project
   MM_Start_Vis(1,0,2,init_jps)
   ;get planned path from NO.1 Mech-Vision project; 2nd argument (1) means getting pose in JPs
   MM_Get_Vispath(1,1,pos_num,vis_pos_num,status)
   ;check whether planned path has been got from Mech-Vision successfully
   IF status<> 1103 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=1003 means no point cloud in ROI
      ;e.g.: status=1002 means no vision results
      halt
   ENDIF
   ;save waypoints of the planned path to local variables one by one
   MM_Get_Jps(1,Xpick_point1,label[1],toolid[1])
   MM_Get_Jps(2,Xpick_point2,label[2],toolid[2])
   MM_Get_Jps(3,Xpick_point3,label[3],toolid[3])
   ;follow the planned path to pick
   ;move to approach waypoint of picking
   PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0] ;
   ;move to picking waypoint
   PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0] ;
   ;add object grasping logic here, such as "$OUT[1]=TRUE"
   halt
   $OUT[131] = False
   $OUT[132] = True
   ;move to departure waypoint of picking
   PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0];
   ;move to intermediate waypoint of placing
   PTP drop_waypoint CONT Vel=100 % PDAT4 Tool[1] Base[0];
   ;move to approach waypoint of placing
   LIN drop_app Vel=1 m/s CPDAT2 Tool[1] Base[0] ;
   ;move to placing waypoint
   LIN drop Vel=0.3 m/s CPDAT3 Tool[1] Base[0] ;
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   $OUT[131] = True
   $OUT[132] = False
   ;move to departure waypoint of placing
   LIN drop_app Vel=1 m/s CPDAT2 Tool[1] Base[0] ;
   ;move back to robot home position
   PTP HOME Vel=100 % DEFAULT;
GOTO Init
END