サンプルプログラム12：MM_S12_Viz_ForLoop

現在ご覧いただいているのは最新版の内容です（V2.1.2）。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ ご利用中のバージョンが分からない場合や、サポートが必要な場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

ロボットがMech-Vizプロジェクトをトリガーして実行し、計画された経路を取得します。その後、ループで計画された経路を保存し、把持および配置を実行します。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/FANUC/sample/MM_S12_Viz_ForLoop。

必要なプロジェクト

Mech-VisionとMech-Vizプロジェクト

使用前提

  1. 標準インターフェース通信設定 が完了しました。

  2. 自動キャリブレーション が完了しました。
このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S12_Viz_ForLoopサンプルプログラムのコードと関連する説明です。

MM_S2_Viz_Basicは計画された経路点を一つずつ保存しますが、このサンプル（太字部分のコード）はループを使用して計画された経路点を保存します。そのため、MM_S2_Viz_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S2_Viz_Basicサンプルの説明 をご参照ください）。 
   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Viz ;
   3:  !project and get planned path, ;
   4:  !get poses using for-loop ;
   5:  !structure ;
   6:  !Mech-Mind, 2023-12-25 ;
   7:  !-------------------------------- ;
   8:   ;
   9:  !set current uframe NO. to 0 ;
  10:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  11:  !set current tool NO. to 1 ;
  12:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  13:  !move to robot home position ;
  14:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  15:  !initialize communication ;
  16:  !parameters(initialization is ;
  17:  !required only once) ;
  18:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  19:  !move to image-capturing position ;
  20:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  21:  !trigger Mech-Viz project ;
  22:  ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10) ;
  23:  !get planned path, 1st argument ;
  24:  !(1) means getting pose in JPs ;
  25:  ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
  26:  !check whether planned path has ;
  27:  !been got from Mech-Viz ;
  28:  !successfully ;
  29:  ﾓｼ ﾚｼﾞ[53]<>2100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  30:  !save waypoints of the planned ;
  31:  !path to local variables using ;
  32:  !for-loop structure ;
  33:  FOR ﾚｼﾞ[100]=1 TO ﾚｼﾞ[51] ;
  34:  ﾚｼﾞ[101]=59+ﾚｼﾞ[100]    ;
  35:  ﾚｼﾞ[102]=69+ﾚｼﾞ[100]    ;
  36:  ﾚｼﾞ[103]=79+ﾚｼﾞ[100]    ;
  37:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(ﾚｼﾞ[100],ﾚｼﾞ[101],ﾚｼﾞ[102],ﾚｼﾞ[103]) ;
  38:  ENDFOR ;
  39:  !follow the planned path to pick, ;
  40:  !in this example waypoint 2 ;
  41:  !(PR[61]) is picking waypoint ;
  42:  !move to approach waypoint ;
  43:  !of picking ;
  44:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ    ;
  45:  !move to picking waypoint ;
  46:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ    ;
  47:  !add object grasping logic here, ;
  48:  !such as "DO[1]=ON" ;
  49:  ｲﾁｼﾞﾃｲｼ ;
  50:  !move to departure waypoint ;
  51:  !of picking ;
  52:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ    ;
  53:  !move to intermediate waypoint ;
  54:  !of placing ;
  55:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  56:  !move to approach waypoint ;
  57:  !of placing ;
  58:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  59:  !move to placing waypoint ;
  60:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ    ;
  61:  !add object releasing logic here, ;
  62:  !such as "DO[1]=OFF" ;
  63:  ｲﾁｼﾞﾃｲｼ ;
  64:  !move to departure waypoint ;
  65:  !of placing ;
  66:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  67:  !move back to robot home position ;
  68:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  69:  ｼｭｳﾘｮｳ ;
  70:   ;
  71:  ﾗﾍﾞﾙ[99:vision error] ;
  72:  !add error handling logic here ;
  73:  !according to different ;
  74:  !error codes ;
  75:  !e.g.: status=2038 means no ;
  76:  !point cloud in ROI ;
  77:  ｲﾁｼﾞﾃｲｼ ;

上記のサンプルプログラムの処理流れは、下図の通りです。

sample12

下表は、ループで計画された経路を保存するコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。

処理流れ コートと説明

ループで計画された経路を保存

 
  32:  !for-loop structure ;
  33:  FOR ﾚｼﾞ[100]=1 TO ﾚｼﾞ[51] ;
  34:  ﾚｼﾞ[101]=59+ﾚｼﾞ[100]    ;
  35:  ﾚｼﾞ[102]=69+ﾚｼﾞ[100]    ;
  36:  ﾚｼﾞ[103]=79+ﾚｼﾞ[100]    ;
  37:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(ﾚｼﾞ[100],ﾚｼﾞ[101],ﾚｼﾞ[102],ﾚｼﾞ[103]) ;
  38:  ENDFOR ;

  • 33行目：FORは以下のループプログラム部分を示します。ﾚｼﾞ[100]はループの回数を制御します（ﾚｼﾞ[100]は1から始まり、毎回ループ後に1増加し、ﾚｼﾞ[51]より大きくなるとループが終了します）。ﾚｼﾞ[51]は MM_GET_VIZ コマンドにおける2番目のパラメータが表す数値レジスタで、このレジスタはビジョンシステムが返す経路点の数を保存します。したがって、ﾚｼﾞ[100]は計画された経路における現在の経路点の番号を示します。

  • 34行目～36行目：ﾚｼﾞ[101]、ﾚｼﾞ[102]、ﾚｼﾞ[103]は、それぞれ現在の経路点に対応する関節角度、ラベル、ロボットハンド番号に使用されるレジスタ番号を示します。

  • 37行目：MM_GET_JPS コマンドは、ある経路点の関節角度、ラベル、およびロボットハンド番号を指定されたレジスタに保存します。したがって、このコマンドはﾚｼﾞ[100]番目の経路点の関節角度、ラベル、ロボットハンド番号をそれぞれﾚｼﾞ[101]、ﾚｼﾞ[102]、ﾚｼﾞ[103]に保存することを意味します。

このサンプルで計画された経路に3つの経路点があると仮定すると、上記のループは MM_S2_Viz_Basic サンプルで次の3つのコマンドに相当します。

  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;

この情報は役に立ちましたか？

ご意見・ご要望がございましたら、以下よりお寄せください：

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。

  • Preference
  • 同意する
  • 拒否する