샘플 프로그램 20: MM_S20_Viz_PlanAllVision

현재 최신 버전 (2.1.2)에 대한 매뉴얼을 보고 계십니다. 다른 버전에 액세스하려면 페이지 오른쪽 상단 모서리에 있는 '버전 전환' 버튼을 클릭하세요.

■ 현재 사용하고 있는 제품의 버전이 확실하지 않은 경우에는 언제든지 당사 기술 지원팀에 문의하시기 바랍니다.

프로그램 소개

기능 설명

로봇이 Mech-Viz 프로젝트 실행을 트리거한 후 루프를 통해 모든 계획된 경로를 획득하여 피킹 및 배치 작업을 수행합니다. 이 샘플에서는 카메라가 이미지를 한 번만 캡처하면 Mech-Viz가 모든 비전 결과에 대한 피킹 경로를 계획합니다. 일반적으로 멀티 피킹 시나리오에 적용합니다.

파일 경로

Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 통신 구성 요소/Robot_Interface/KUKA/sample/MM_S20_Viz_PlanAllVision 경로를 사용하여 파일을 찾을 수 있습니다.

필요한 프로젝트

Mech-Vision와 Mech-Viz 프로젝트

Mech-Viz 프로젝트는 다음 구성을 미리 설정해야 함: 비전 이동 스텝의 비전 결과를 재사용하기는 활성화해야 합니다.
sample20 1

사용 전제 조건

  1. 표준 인터페이스 통신 구성이 완료됩니다.

  2. 자동 캘리브레이션이 완료됩니다.

이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오.

프로그램 설명

다음에는 MM_S20_Viz_PlanAllVision 샘플 프로그램의 코드와 관련 설명입니다.

MM_S2_Viz_Basic 샘플과 비하면, 이 샘플은 루프를 통해 모든 계획된 경로를 획득하여 피킹 및 배치 작업을 수행하는 기능만 수정되었습니다.(이 부분의 코드는 굵게 표시됨) 따라서, MM_S20_Viz_PlanAllVisiont의 MM_S2_Viz_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S2_Viz_Basic샘플 프로그램 설명을 참조하십시오).
DEF  MM_S20_Viz_PlanAllVision ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Viz project, plan all
; vision results and get all planned results using
; command 210
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
   ;move to robot home position
PTP HOME Vel=100 % DEFAULT
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
RECAP:
   ;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger Mech-Viz project
   MM_Start_Viz(2,init_jps)
   ;get planned path
   MM_Get_PlanData(0,3,pos_num,vis_pos_num,status)
   ;check whether planned path has been got from Mech-Viz successfully
   IF status<> 2100 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=2038 means no point cloud in ROI
      halt
   ENDIF
   ;save waypoints of the planned path to local variables one by one
   FOR count=1 TO pos_num
      MM_Get_PlanJps(count,3,pick_point[count],move_type[count],tool_num[count],speed[count])
   ENDFOR
   ;parse pick cycle count, here suppose 3 points per planned path
   pick_cnt = pos_num / 3
   residual = pos_num - pick_cnt*3
   ;check if parsed data is valid; if not, retry to get planned path or add some error handling logic
   IF (pick_cnt<1) OR (residual<>0) THEN
      halt
      GOTO RECAP
   ENDIF
   ;repeatedly run pick-and-place cycle using for-loop
   FOR i=1 TO pick_cnt
      count=(i-1)*3
      Xpick_point1=pick_point[1+count]
      Xpick_point2=pick_point[2+count]
      Xpick_point3=pick_point[3+count]
      ;move to intermediate waypoint of picking
PTP pick_waypoint CONT Vel=50 % PDAT7 Tool[1] Base[0]
      ;follow the planned path to pick
PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0]
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
      ;add object grasping logic here, such as "$OUT[1]=TRUE"
      halt
PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0]
      ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
      ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
      ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT4 Tool[1] Base[0]
      ;add object releasing logic here, such as "$OUT[1]=FALSE"
      halt
      ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
      ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ENDFOR
   ;finish pick and-place cycle, and jump back to camera capturing
   GOTO RECAP
END

위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.

sample20

아래 표는 새롭게 추가된 기능의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.

워크플로 코드와 설명

계획 경로를 획득하기

;get planned path
MM_Get_PlanData(0,3,pos_num,vis_pos_num,status)
  • MM_Get_PlanData:계획 경로를 획득하는 명령어. 이 명령어를 통해 획득된 비전 이동 웨이포인트는 포즈와 비전 이동 계획 결과, 사용자 정의 데이터가 포함되지만, MM_Get_VizData 명령어를 통해 획득된 비전 이동 웨이포인트는 사용자 정의 데이터와 비전 이동 계획 결과가 포함되지 않습니다.

  • 0: Mech-Viz에서 계획 경로를 획득합니다.

  • 3: 반환될 것으로 예상되는 데이터 포맷, 즉 "포즈(관절 각도 유형), 이동 유형, 말단장치의 번호, 속도, Mech-Viz 비전 이동 계획 결과, 사용자 정의 출력 데이터 1..., 사용자 정의 출력 데이터 N" 포맷으로 데이터가 반환됩니다.

  • pose_num: 이 변수는 비전 시스템이 반환한 웨이포인트의 개수를 저장합니다.

  • vis_pose_num: 이 변수는 마지막 비전 이동 웨이포인트(피킹 웨이포인트)의 전체 경로 내 위치 번호를 저장합니다.

  • status: 이 변수는 명령어 실행 상태 코드를 저장하는 것입니다.

루프를 통해 계획 경로를 저장하기

FOR count=1 TO pos_num
MM_Get_PlanJps(count,3,pick_point[count],move_type[count],tool_num[count],speed[count])
ENDFOR
  • 1번째 줄: FOR는 아래 코드가 반복 실행되는 루프 프로그램임을 나타냅니다. count는 반복 횟수를 제어하며, 1부터 시작하여 매 반복마다 1씩 증가하고, pose_num보다 커지면 루프가 종료됩니다. pose_num은 MM_Get_PlanData 명령어의 세 번째 파라미터로, 비전 시스템이 반환한 웨이포인트 개수를 나타냅니다.

  • 2번째 줄: MM_Get_PlanJps 명령어는 특정 웨이포인트의 관절 각도, 이동 유형, 말단장치 번호 및 속도를 각각 지정된 변수에 저장하는 것을 의미합니다. 따라서 이 명령어는 count 번째 웨이포인트의 관절 각도, 이동 유형, 말단장치 번호 및 속도를 pick_point[count], move_type[count], tool_num[count], tool_num[count] 변수에 차례대로 저장하는 것을 나타냅니다.

  • 3번째 줄: FOR 순환을 종료합니다.

pick_cnt 및 residual를 계산하기

;parse pick cycle count, here suppose 3 points per planned path
pick_cnt = pos_num / 3
residual = pos_num - pick_cnt*3

본 샘플에서는 매번 계획된 피킹 경로에 3개의 웨이포인트가 포함된다고 가정합니다. pick_cnt = "pos_num / 3"는 pos_num을 3로 나눈 몫을 의미합니다. "pos_num - pick_cnt*3"는 pos_num을 3로 나눈 나머지를 의미합니다. pick_cnt는 계획된 총 피킹 횟수를 나타냅니다. residual 값이 0이 아닌 경우, 특정 계획된 피킹 웨이포인트 개수가 3개 미만임을 의미하며, 이는 경로 계획에 이상이 발생했음을 나타내므로 다시 계획을 수행해야 합니다.

경로 계획 오류가 발생했는지 확인하기

IF (pick_cnt<1) OR (residual<>0) THEN
   halt
   GOTO RECAP
ENDIF

피킹 횟수 pick_cnt가 1보다 작은 경우 또는 residual 값이 0이 아닌 경우, 경로 계획 중 오류가 발생했음을 의미하며 사용자는 여기에서 코드 처리를 추가해야 합니다. 예를 들어 Mech-Viz 프로젝트를 다시 트리거하여 계획 경로를 획득하는 코드를 추가합니다.

루프를 통해 피킹 및 배치 작업을 실행하기

   FOR i=1 TO pick_cnt
      count=(i-1)*3
      Xpick_point1=pick_point[1+count]
      Xpick_point2=pick_point[2+count]
      Xpick_point3=pick_point[3+count]
      ;move to intermediate waypoint of picking
PTP pick_waypoint CONT Vel=50 % PDAT7 Tool[1] Base[0]
      ;follow the planned path to pick
PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0]
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
      ;add object grasping logic here, such as "$OUT[1]=TRUE"
      halt
PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0]
      ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
      ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
      ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT4 Tool[1] Base[0]
      ;add object releasing logic here, such as "$OUT[1]=FALSE"
      halt
      ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
      ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ENDFOR

위의 코드는 FOR 루프 내에서 로봇이 매번 계획된 3개의 웨이포인트로 이동하여 피킹 작업을 수행한 후, 이어서 배치 작업을 실행하는 것을 나타냅니다. i는 순환 횟수를 제어하는 변수로, 1부터 시작하여 매 순환마다 1씩 증가하며, 피킹 횟수 pick_cnt보다 커지면 루프가 종료됩니다. i가 1 증가할 때마다 count가 3 증가하며, 이를 통해 [1+count] ~ [3+count]는 매번 계획된 3개의 웨이포인트가 전체 계획 경로에서 차지하는 번호를 나타냅니다.

이 페이지가 도움이 되었습니까?

다음 방법을 통해 피드백을 보내주실 수 있습니다:

저희는 귀하의 개인정보를 소중히 다룹니다.

당사 웹사이트는 최상의 사용자 경험을 제공하기 위해 쿠키를 사용하고 있습니다. "모두 수락"을 클릭하시면 쿠키 사용에 동의하시는 것이며, "모두 거부"를 클릭하시면 이 웹사이트 방문 시 귀하의 정보가 추적되거나 기억되지 않도록 단일 쿠키만 사용됩니다.