샘플 프로그램: MM_S21_Vis_As_Uframe

현재 최신 버전 (2.2.1)에 대한 매뉴얼을 보고 계십니다. 다른 버전에 액세스하려면 페이지 오른쪽 상단 모서리에 있는 '버전 전환' 버튼을 클릭하세요.

■ 현재 사용하고 있는 제품의 버전이 확실하지 않은 경우에는 언제든지 당사 기술 지원팀에 문의하시기 바랍니다.

프로그램 소개

기능 설명

로봇이 Mech-Vision 프로젝트를 트리거하여 비전 결과를 취득합니다. 취득한 비전 결과를 대상 물체 좌표계로 사용하여, 픽업 및 배치 동작 공정을 수행합니다.

파일 경로

Mech-Vision 및 Mech-Viz의 설치 디렉터리로 이동하여 Communication Component/Robot_Interface/ABB/sample/MM_S21_Vis_As_Uframe 경로를 사용하여 파일을 찾을 수 있습니다.

RobotWare6 시스템에서는 파일의 확장명은 .mod입니다. RobotWare7 시스템에서는 사용자는 .mod를 .modx로 소정합니다.

필요한 프로젝트

Mech-Vision 프로젝트

사용 전제 조건

표준 인터페이스 통신 구성이 완료됩니다.
자동 캘리브레이션이 완료됩니다.

이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오.

프로그램 설명

다음에는MM_S21_Vis_As_Uframe 샘플 프로그램의 코드와 관련 설명입니다.

MM_S1_Vis_Basic 샘플과 달리, 본 샘플은 비전 결과를 사용자 좌표계(예: 대상 물체 좌표계)로 사용하여 피킹을 수행합니다. 따라서 MM_S1_Vis_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S1_Vis_Basic 샘플 프로그램 설명을 참조하십시오).

MODULE MM_S21_Vis_As_Uframe
    !----------------------------------------------------------
    ! FUNCTION: trigger Mech-Vision project and get vision result
    ! Mech-Mind, 2026-1-28
    !----------------------------------------------------------
    !define local num variables
    LOCAL VAR num pose_num:=0;
    LOCAL VAR num status:=0;
    LOCAL VAR num label:=0;
    LOCAL VAR num toolid:=0;
    !define local joint&pose variables
    LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
    LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
    LOCAL PERS robtarget camera_capture:=[[380.58,24.66,583.22],[0.00392748,-0.815898,0.578164,-0.00464691],[0,0,-2,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
    LOCAL PERS robtarget pick_waypoint:=[[502.38,26.91,592.51],[0.00179326,-0.458155,0.888868,-0.0019068],[0,-1,-1,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
    LOCAL PERS robtarget pickpoint:=[[0,0,0],[1,0,0,0],[0,-1,-1,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
    LOCAL PERS robtarget Wobjpoint:=[[0,0,0],[1,0,0,0],[0,0,0,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
    LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
    LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
    !define LOCAL tooldata variables
    LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];
    !define LOCAL wobjdata variables
    TASK PERS wobjdata MM_Wobj:=[FALSE,TRUE,"",[[0,0,0],[1,0,0,0]],[[639.64,-59.7632,41.2964],[0.0326084,-0.429607,0.901024,0.0503118]]];

    PROC Sample_21()
        !set the acceleration parameters
        AccSet 50,50;
        !set the velocity parameters
        VelSet 50,1000;
        !move to robot home position
        MoveAbsJ home\NoEOffs,v3000,fine,gripper1\WObj:=MM_Wobj;
        !initialize communication parameters (initialization is required only once)
        MM_Init_Socket "127.0.0.1", 50000, 300;
        !move to image-capturing position
        MoveL camera_capture,v1000,fine,gripper1;
        !open socket connection
        MM_Open_Socket status;
        IF status=3099 THEN
            TPWrite "MM: Communication Error";
            STOP;
        ENDIF
        !trigger NO.1 Mech-Vision project
        MM_Start_Vis 1,0,2,snap_jps,status;
        IF status<>1102 THEN
            !add error handling logic here according to different error codes
            TPWrite "MM: Status Error";
            STOP;
        ENDIF
        !get vision result from NO.1 Mech-Vision project
        stop;
        MM_Get_VisData 1,pose_num,status;
        !check whether vision result has been got from Mech-Vision successfully
        IF status<>1100 THEN
            !add error handling logic here according to different error codes
            !e.g.: status=1003 means no point cloud in ROI
            !e.g.: status=1002 means no vision result
            Stop;
        ENDIF
        !close socket connection
        MM_Close_Socket;
        !save first vision point data to local variables
        MM_Get_Pose 1,Wobjpoint,label,toolid;
        !Convert the visual points to the workpiece coordinates
        MM_Wobj.oframe.trans:=Wobjpoint.trans;
        MM_Wobj.oframe.rot:=Wobjpoint.rot;
        !move to intermediate waypoint of picking
        MoveJ pick_waypoint,v1000,z50,gripper1;
        !move to approach waypoint of picking
        MoveL RelTool(pickpoint,0,0,-100), v1000, fine, gripper1\WObj:=MM_Wobj;
        !move to picking waypoint
        MoveL pickpoint, v300, fine, gripper1\WObj:=MM_Wobj;
        !add object grasping logic here, such as "setdo DO_1, 1;"
        Stop;
        !move to departure waypoint of picking
        MoveL RelTool(pickpoint,0,0,-100), v1000, fine, gripper1\WObj:=MM_Wobj;
        !move to intermediate waypoint of placing
        MoveJ drop_waypoint,v1000,z50,gripper1;
        !move to approach waypoint of placing
        MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
        !move to placing waypoint
        MoveL drop,v300,fine,gripper1;
        !add object releasing logic here, such as "setdo DO_1, 0;"
        Stop;
        !move to departure waypoint of placing
        MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
        !move back to robot home position
        MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
    ENDPROC
ENDMODULE

위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.

아래 표는 새롭게 추가된 기능의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.

워크플로 코드와 설명

변수를 정의하기

    LOCAL PERS robtarget pickpoint:=[[0,0,0],[1,0,0,0],[0,-1,-1,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
    LOCAL PERS robtarget Wobjpoint:=[[0,0,0],[1,0,0,0],[0,0,0,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];

Wobjpoint는 Mech-Vision에서 획득한 비전 포인트를 저장하는 데 사용됩니다. pickpoint 변수는 대상 물체 좌표계에서의 피킹 포즈를 저장하는 데 사용됩니다.

비전 포인트의 TCP 포즈를 변환하여 저장하고, 대상 물체 좌표계 MM_Wobj에 할당합니다

        !save first vision point data to local variables
        MM_Get_Pose 1,Wobjpoint,label,toolid;
        !Convert the visual points to the workpiece coordinates
        MM_Wobj.oframe.trans:=Wobjpoint.trans;
        MM_Wobj.oframe.rot:=Wobjpoint.rot;

먼저 MM_Get_Pose 명령어를 통해 비전 결과를 변수 Wobjpoint에 저장한 후, Wobjpoint의 위치값과 회전값을 각각 오브젝트 대상 물체 좌표계인 MM_Wobj의 원점 위치와 원점 자세에 할당합니다. 이 두 명령어는 대상 물체 좌표계를 동적으로 업데이트하는 데 사용됩니다.

피킹 및 배치를 수행하기

        !move to intermediate waypoint of picking
        MoveJ pick_waypoint,v1000,z50,gripper1;
        !move to approach waypoint of picking
        MoveL RelTool(pickpoint,0,0,-100), v1000, fine, gripper1\WObj:=MM_Wobj;
        !move to picking waypoint
        MoveL pickpoint, v300, fine, gripper1\WObj:=MM_Wobj;
        !add object grasping logic here, such as "setdo DO_1, 1;"
        Stop;
        !move to departure waypoint of picking
        MoveL RelTool(pickpoint,0,0,-100), v1000, fine, gripper1\WObj:=MM_Wobj;
        !move to intermediate waypoint of placing
        MoveJ drop_waypoint,v1000,z50,gripper1;
        !move to approach waypoint of placing
        MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
        !move to placing waypoint
        MoveL drop,v300,fine,gripper1;
        !add object releasing logic here, such as "setdo DO_1, 0;"
        Stop;
        !move to departure waypoint of placing
        MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
        !move back to robot home position
        MoveAbsJ home\NoEOffs,v3000,fine,gripper1;

프로그램을 "로봇을 픽 접근점으로 이동" 단계까지 처음 실행하기 전에, 대상 물체 좌표계에서 픽 포인트를 티칭해야 합니다.

MoveL RelTool(pickpoint,0,0,-100), v1000, fine, gripper1\WObj:=MM_Wobj;: 대상 물체 좌표계 MM_Wobj를 기준으로 로봇을 픽 접근점으로 이동합니다.
MoveL pickpoint, v300, fine, gripper1\WObj:=MM_Wobj;: 대상 물체 좌표계 MM_Wobj를 기준으로 로봇을 픽 포인트로 이동합니다.
MoveL RelTool(pickpoint,0,0,-100), v1000, fine, gripper1\WObj:=MM_Wobj;: 대상 물체 좌표계 MM_Wobj를 기준으로 로봇을 픽 이탈점으로 이동합니다.

이 페이지가 도움이 되었습니까?

피드백 남기기

지원해 주셔서 감사합니다!

다음 방법을 통해 피드백을 보내주실 수 있습니다:

저희는 귀하의 개인정보를 소중히 다룹니다.

당사 웹사이트는 최상의 사용자 경험을 제공하기 위해 쿠키를 사용하고 있습니다. "모두 수락"을 클릭하시면 쿠키 사용에 동의하시는 것이며, "모두 거부"를 클릭하시면 이 웹사이트 방문 시 귀하의 정보가 추적되거나 기억되지 않도록 단일 쿠키만 사용됩니다.

모두 수락

모두 거부