FANUC Example Program¶

This section introduces the example program provided with Mech-Center and the operations required to perform an actual pick-and-place task.

The example program mm_sample can be found in xxx/Mech-Center-xxx/Robot_Interface/FANUC/sample.

Check the section corresponding to your own application setup:

Obtain Vision Results from Mech-Vision
Obtain Planned Path from Mech-Viz

Before running the program, please make sure that:

You have loaded the Standard Interface program onto the robot and can establish communcation with Mech-Center.
You have completed the extrinsic parameter calibration with the calibration program or by manually adding calibration points.
Mech-Vision and Mech-Viz projects are created and set to autoload.
The Project list in Mech-Center ‣ Deployment Settings ‣ Mech-Vision is synced by clicking on , and the order of Mech-Vision projects have been adjusted according to actual needs.
The TCP has been correctly specified.
The robot speed is set to a low value, so that the operator can notice any unexpected behavior before accidents occur.

Obtain Vision Results from Mech-Vision¶

 !FUNCTION:Eye to Hand simple pick ;
 !MechMind,2022-05-30 ;
  ;
 !SET Tool ;
 UTOOL_NUM=1 ;
 !Move to HOME Position ;
J P[1] 100% FINE    ;
 !Move to Camera capture Position ;
L P[2] 3000mm/sec FINE    ;
 !Set IP address and Port ;
 CALL MM_INIT_SKT('8','192.168.1.20',50000,1) ;
 WAIT    .10(sec) ;
 !Set Vision Recipe ;
 //CALL MM_SET_MOD(1,1) ;
 !Run Vision Project ;
 CALL MM_START_VIS(1,1,2) ;
 WAIT   1.00(sec) ;
 CALL MM_GET_VIS(1,50,51,52) ;
 IF (R[52]<>1100) THEN ;
 PAUSE ;
 ENDIF ;
 CALL MM_GET_POS(1,60,70,80) ;
L PR[60] 800mm/sec CNT100 Offset,PR[1]    ;
L PR[60] 800mm/sec FINE    ;
 !Add object grasping logic here ;
  ;
L PR[60] 800mm/sec CNT100 Offset,PR[1]    ;
 !Add transition point ;
L P[3] 800mm/sec FINE    ;
 !Move to DROP Position ;
L P[4] 800mm/sec CNT100 Offset,PR[2]    ;
L P[4] 200mm/sec FINE    ;
 !Add object releasing logic here ;
  ;
L P[4] 800mm/sec CNT100 Offset,PR[2]    ;
 !Move to HOME Position ;
J P[1] 100% FINE    ;

Program Logic¶

Move the robot to HOME position.
Move the robot to the image-capturing pose.
Initialize communication with MM_INIT_SKT. For detailed information, please refer to FANUC Standard Interface Commands.
If parameter recipes are used in the Mech-Vision project, the recipe to be used is set with MM_SET_MOD. For detailed information, please refer to FANUC Standard Interface Commands.
Run the Mech-Vision project with MM_START_VIS.
Wait for 1 second. Under Eye-In-Hand, this WAIT instruction is required to make sure the robot stays still until image acquisition is completed. Under Eye-To-Hand, this WAIT instruction is not needed if there is a motion procedure between MM_START_VIS and MM_GET_VIS
Obtain the vision results from Mech-Vision.
Check if the returned status code indicates any error. If an error code is returned, the program is paused.
Move the robot to the picking pose and perform picking.
Move the robot to a waypoint between the picking pose and placing pose.
Move the robot to the set placing pose and perform placing.
Return the robot to HOME position.

The following parts should be modified according to your actual needs.

Define HOME position¶

Please set the HOME position in register P[1].

Define the TCP¶

The TCP in this example is defined as UTOOL_NUM=1. Please change the value 1 according to the actual TCP values.

Teach the image-capturing pose¶

Please record the image-capturing pose in register P[2].

Teach the Waypoint(s)¶

Waypoints are intermediate poses between the picking pose and placing pose. They are used to ensure that the robot doesn’t collide with the surrounding when moving between the picking and placing poses.

The waypoints in this example is saved in P[3]. You can add one or more waypoints.

Teach the Placing Pose¶

Please record the placing pose in register P[4].

Define Z-Offset from Picking/Placing Pose¶

Z-offset distances relative to the tool frame from the picking/placing pose are used to ensure collision doesn’t occur when the robot is approaching or departing the picking/placing pose.

Adjust the following commands according to your actual needs.

L PR[60] 800mm/sec CNT100 Offset,PR[1]: the Z-offset when approaching the picking pose is saved in PR[1].
L PR[60] 800mm/sec CNT100 Offset,PR[1]: the Z-offset when departing the picking pose is saved in register PR[1].
L P[4] 800mm/sec CNT100 Offset,PR[2]: the Z-offset when approaching placing pose is saved in register PR[2].
L P[4] 800mm/sec CNT100 Offset,PR[2]: the Z-offset when departing the placing pose is saved in register PR[2].

Add Object Grasping and Releasing Logics¶

Add logic for controlling the tool action when picking or placing the object.

Obtain Planned Path from Mech-Viz¶

 !FUNCTION:Eye to Hand simple pick ;
 !and place with Mech-Viz ;
 !MechMind,2022-05-30 ;
  ;
 !SET Tool ;
 UTOOL_NUM=1 ;
 !Move to HOME Position ;
J P[1] 100% FINE    ;
 !Move to Camera capture Position ;
L P[2] 3000mm/sec FINE    ;
 !Set IP address and Port ;
 CALL MM_INIT_SKT('8','192.168.1.20',50000,1) ;
 WAIT    .10(sec) ;
 !Set Vision Recipe ;
 //CALL MM_SET_MOD(1,1) ;
 !Run Viz Project ;
 CALL MM_START_VIZ(1) ;
 WAIT    .10(sec) ;
 !set branch exitport ;
 //CALL MM_SET_BCH(1,1) ;
 !get planned path ;
 CALL MM_GET_VIZ(2,50,51,52,53) ;
 IF (R[53]<>2100) THEN ;
 PAUSE ;
 ENDIF ;
 CALL MM_GET_POS(1,60,70,80) ;
 CALL MM_GET_POS(2,61,71,81) ;
 CALL MM_GET_POS(3,62,72,82) ;
 !follow the planned path to pick ;
L PR[60] R[80]mm/sec FINE    ;
L PR[61] R[81]mm/sec FINE    ;
 !Add object grasping logic here ;
  ;
L PR[62] R[82]mm/sec FINE    ;
 !Add transition point ;
L P[3] 800mm/sec FINE    ;
 !Move to DROP Position ;
L P[4] 800mm/sec CNT100 Offset,PR[2]    ;
L P[4] 200mm/sec FINE    ;
 !Add object releasing logic here ;
  ;
L P[4] 800mm/sec CNT100 Offset,PR[2]    ;
 !Move to HOME Position ;
J P[1] 100% FINE    ;